blob: 7ad6a9ad4696e3ab511709a54e5cf1e424fc1f96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 247837 2015-09-28 19:16:18Z foutrelis $
# Maintainer (Arch): Andreas Radke <andyrtr@archlinux.org>
pkgname=cups-filters
pkgver=1.0.76
pkgrel=2.parabola1
pkgdesc="OpenPrinting CUPS Filters, without foomatic-db-nonfree recommendation"
arch=('i686' 'x86_64')
url="http://www.linuxfoundation.org/collaborate/workgroups/openprinting"
license=('GPL')
depends=('lcms2' 'poppler=0.36.0' 'qpdf')
makedepends=('ghostscript' 'ttf-dejavu' 'python2') # ttf-dejavu for make check
optdepends=('ghostscript: for non-PostScript printers to print with CUPS to convert PostScript to raster images'
'foomatic-db: drivers use Ghostscript to convert PostScript to a printable form directly'
'foomatic-db-engine: drivers use Ghostscript to convert PostScript to a printable form directly')
backup=(etc/fonts/conf.d/99pdftoopvp.conf
etc/cups/cups-browsed.conf)
source=(http://www.openprinting.org/download/cups-filters/$pkgname-$pkgver.tar.xz)
provides=('foomatic-filters')
replaces=('foomatic-filters' "${pkgname}-libre" "${pkgname}-parabola")
conflicts=('foomatic-filters' "${pkgname}-libre" "${pkgname}-parabola")
md5sums=('92e14b4f52a320c8d8b8176918bd4a8c')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--localstatedir=/var \
--with-rcdir=no \
--enable-avahi \
--with-browseremoteprotocols=DNSSD,CUPS \
--with-test-font-path=/usr/share/fonts/TTF/DejaVuSans.ttf
make
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir/" install
# add upstream systemd support file
install -Dm644 utils/cups-browsed.service ${pkgdir}/usr/lib/systemd/system/cups-browsed.service
sed -i "s|/usr/sbin/cups-browsed|/usr/bin/cups-browsed|" ${pkgdir}/usr/lib/systemd/system/cups-browsed.service
sed -i "s|cups.service|org.cups.cupsd.service|g" ${pkgdir}/usr/lib/systemd/system/cups-browsed.service
# use lp group from cups pkg FS#36769
chgrp -R lp ${pkgdir}/etc/cups
}
|
