blob: cd2004cc05f14e6539c772eec56ed5dd269df24f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer (arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contrbutor: bill-auger <bill-auger@programmer.net>
# parabola changes and rationale:
# - remove foomatic-db-nonfree recommendation
# - pin to strongly-coupled dependency versions
# - substitute 'systemd' dependency with 'udev'
pkgname=cups-filters
pkgver=1.28.9
pkgrel=1
pkgrel+=.parabola1
pkgdesc="OpenPrinting CUPS Filters"
pkgdesc+=", without foomatic-db-nonfree recommendation"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="https://wiki.linuxfoundation.org/openprinting/cups-filters"
license=('custom')
depends=('lcms2' 'poppler' 'qpdf' 'imagemagick' 'liblouis' 'ijs' 'libcups>=2.2.6-2' 'systemd')
depends=( ${depends[@]/systemd/udev} )
makedepends=('ghostscript' 'ttf-dejavu' 'python' 'mupdf-tools') # ttf-dejavu for make check
makedepends_i686=('pkgconf')
optdepends=('ghostscript: for non-PostScript printers to print with CUPS to convert PostScript to raster images'
'foomatic-db: drivers use Ghostscript to convert PostScript to a printable form directly'
'foomatic-db-engine: drivers use Ghostscript to convert PostScript to a printable form directly'
'antiword: to convert MS Word documents'
'docx2txt: to convert Microsoft OOXML text from DOCX files')
backup=(etc/cups/cups-browsed.conf)
source=(https://www.openprinting.org/download/cups-filters/$pkgname-$pkgver.tar.xz)
sha256sums=('2f69372a4fa76dc91e54b4c98ab4c65368e3dfbde92456205c98a39573e860ae')
build() {
cd "$pkgname"-$pkgver
./configure --prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--localstatedir=/var \
--with-rcdir=no \
--enable-avahi \
--with-browseremoteprotocols=DNSSD,CUPS \
--enable-auto-setup-driverless \
--with-test-font-path=/usr/share/fonts/TTF/DejaVuSans.ttf
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd "$pkgname"-$pkgver
make check
}
package() {
# pin to current 'poppler' lib
local poppler_ver=$(pacman -S --print-format='%v' poppler)
depends=( ${depends[@]/poppler/poppler=${poppler_ver}} )
cd "$pkgname"-$pkgver
make DESTDIR="$pkgdir/" install
# add upstream systemd support file
install -Dm644 utils/cups-browsed.service "${pkgdir}"/usr/lib/systemd/system/cups-browsed.service
sed -i "s|/usr/sbin/cups-browsed|/usr/bin/cups-browsed|" "${pkgdir}"/usr/lib/systemd/system/cups-browsed.service
#sed -i "s|cups.service|org.cups.cupsd.service|g" "${pkgdir}"/usr/lib/systemd/system/cups-browsed.service
# use cups group from cups pkg FS#56818
chgrp -R 209 "${pkgdir}"/etc/cups
# license
mkdir -p "${pkgdir}"/usr/share/licenses/${pkgname}
install -m644 "${srcdir}"/${pkgname}-${pkgver}/COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/
}
|
