blob: e56791a534f83af72e7f39ad8365e752a0ac64ae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Maintainer (Arch): Jelle van der Waa <jelle@vdwaa.nl>
# Maintainer (Arch): Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Petrov Roman <nwhisper@gmail.com>
# Contributor (Arch): Andrea Fagiani <andfagiani _at_ gmail dot com>
# Contributor (Arch): Larry Hajali <larryhaja@gmail.com>
# Contributor (Arch): Eli Schwartz <eschwartz93@gmail.com>
# Contributor: David P.<megver83@parabola.nu>
# Contributor: Jesús E.<heckyel@parabola.nu>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
pkgname=calibre
_commit='72011a66bf4f380a8d36c6fd9c3f6069e767539b'
pkgver=3.12.0
pkgrel=2.parabola1
_mathjax_ver=2.6.1
pkgdesc="Ebook management application, without nonfree decompression engine for RAR archives"
arch=('x86_64' 'i686' 'armv7h')
url="https://calibre-ebook.com/"
license=('GPL3')
depends=('python2-six' 'python2-dateutil' 'python2-cssutils' 'python2-dukpy'
'python2-mechanize' 'podofo' 'libwmf'
'chmlib' 'python2-lxml' 'libusbx' 'python2-html5-parser'
'python2-pillow' 'shared-mime-info' 'python2-dnspython' 'python2-msgpack'
'python2-pyqt5' 'python2-psutil' 'libmtp' 'python2-dbus'
'python2-netifaces' 'python2-cssselect' 'python2-apsw' 'qt5-webkit'
'qt5-svg' 'python2-regex' 'python2-pygments' 'mtdev'
'desktop-file-utils' 'gtk-update-icon-cache' 'optipng' 'udisks2')
# we don't want it to break whenever Arch pushes a new icu soname, nor
# is it desirable to have it block every minor-version upgrade when
# it's actually linked against no minor version in particular
depends+=('icu>=60' 'icu<61')
makedepends=('qt5-x11extras' 'xdg-utils')
optdepends=('ipython2: to use calibre-debug'
# TODO: I don't know the mapping from poppler versions to sonames
'poppler=0.61.1: required for converting pdf to html')
replaces=($pkgname-libre)
conflicts=($pkgname-libre)
source=("$pkgname-$pkgver.tar.gz::https://gitlab.com/libreforks/calibre/repository/archive.tar.gz?ref=$pkgver"
"$pkgname-$pkgver.tar.gz.sig::https://gitlab.com/libreforks/calibre/raw/signatures/$pkgname-$pkgver-${_commit}.tar.gz.sig"
"$pkgname-translations.zip::https://github.com/kovidgoyal/${pkgname}-translations/archive/master.zip"
"MathJax-${_mathjax_ver}.tar.gz::https://github.com/kovidgoyal/MathJax/archive/${_mathjax_ver}.tar.gz")
sha256sums=('ee9a4993b290846dbcc242e5116a41111935dbb41355f102569d6871b4386562'
'SKIP'
'6e3f10901910f87f79840aa1222b0dba088ed5393e05c80489cab6db5686c30b'
'c746945d87a4e93ee801a44b6209986bfc901cb2f6c505628a2ed5793422fbb8')
validpgpkeys=('6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78' # David P.
'916FFBC76D2E641BA416BA53364F4E1483446AC5' # Jesús E.
)
prepare() {
# Parabola: rename from gitlab archive
mv "$pkgname-$pkgver-${_commit}" "$pkgname-$pkgver"
cd "${pkgname}-${pkgver}"
# Parabola: link translations to build dir
ln -sfT ../calibre-translations-master translations
# Remove unneeded files
rm -rf resources/${pkgname}-portable.*
# Desktop integration (e.g. enforce arch defaults)
sed -e "/self.create_uninstaller()/,/os.rmdir(config_dir)/d" \
-e "/cc(\['xdg-desktop-menu', 'forceupdate'\])/d" \
-e "/cc(\['xdg-mime', 'install', MIME\])/d" \
-e "s/'ctc-posml'/'text' not in mt and 'pdf' not in mt and 'xhtml'/" \
-e "s/^Name=calibre/Name=Calibre/g" \
-i src/calibre/linux.py
}
build() {
cd "${pkgname}-${pkgver}"
LANG='en_US.UTF-8' python2 setup.py build
LANG='en_US.UTF-8' python2 setup.py gui
# Parabola
LANG='en_US.UTF-8' python2 setup.py iso639
LANG='en_US.UTF-8' python2 setup.py iso3166
LANG='en_US.UTF-8' python2 setup.py translations
LANG='en_US.UTF-8' python2 setup.py resources
LANG='en_US.UTF-8' python2 setup.py man_pages
LANG='en_US.UTF-8' python2 setup.py recent_uas || true
LANG='en_US.UTF-8' python2 setup.py mathjax --path-to-mathjax="${srcdir}/MathJax-${_mathjax_ver}"
}
package() {
cd "${pkgname}-${pkgver}"
install -d "${pkgdir}/usr/share/zsh/site-functions" \
"${pkgdir}"/usr/share/{applications,desktop-directories,icons/hicolor}
install -Dm644 resources/calibre-mimetypes.xml \
"${pkgdir}/usr/share/mime/packages/calibre-mimetypes.xml"
XDG_DATA_DIRS="${pkgdir}/usr/share" LANG='en_US.UTF-8' \
python2 setup.py install --staging-root="${pkgdir}/usr" --prefix=/usr
cp -a man-pages/ "${pkgdir}/usr/share/man"
# Compiling bytecode FS#33392
python2 -m compileall "${pkgdir}/usr/lib/calibre/"
python2 -O -m compileall "${pkgdir}/usr/lib/calibre/"
}
|
