blob: f129ee372c9ac3c00299c4ff822ee159702a6f50 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# $Id$
# Maintainer (Arch): Jelle van der Waa <jelle@vdwaa.nl>
# Maintainer (Arch): Eli Schwartz <eschwartz@archlinux.org>
# Contributor (Arch): Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Petrov Roman <nwhisper@gmail.com>
# Contributor (Arch): Andrea Fagiani <andfagiani _at_ gmail dot com>
# Contributor (Arch): Larry Hajali <larryhaja@gmail.com>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: David P.<megver83@parabola.nu>
# Contributor: Jesús E.<heckyel@parabola.nu>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# parabola changes and rationale:
# - removed decrompession engine for rar archives
pkgname=calibre
pkgver=3.16.0
pkgrel=1.parabola1
pkgdesc="Ebook management application, without nonfree decompression engine for RAR archives"
arch=('x86_64' 'i686' 'armv7h')
url="https://calibre-ebook.com/"
license=('GPL3')
depends=('python2-six' 'python2-dateutil' 'python2-cssutils' 'python2-dukpy'
'python2-mechanize' 'podofo' 'libwmf'
'chmlib' 'python2-lxml' 'libusbx' 'python2-html5-parser'
'python2-pillow' 'shared-mime-info' 'python2-dnspython' 'python2-msgpack'
'python2-pyqt5' 'python2-psutil' 'icu' 'libmtp' 'python2-dbus'
'python2-netifaces' 'python2-cssselect' 'python2-apsw' 'qt5-webkit'
'qt5-svg' 'python2-regex' 'python2-pygments' 'mtdev'
'desktop-file-utils' 'gtk-update-icon-cache' 'optipng' 'udisks2')
makedepends=('qt5-x11extras' 'xdg-utils')
optdepends=('ipython2: to use calibre-debug'
'poppler: required for converting pdf to html'
)
# for updated libre.patch commit id see: https://gitlab.com/libreforks/calibre/tags
_commit='507fbd372a3d6c6f0d1100b88254a1ff'
source=("https://download.calibre-ebook.com/${pkgver}/calibre-${pkgver}.tar.xz"
"https://calibre-ebook.com/signatures/${pkgname}-${pkgver}.tar.xz.sig"
"https://gitlab.com/libreforks/calibre/uploads/$_commit/libre.patch")
sha256sums=('2a47cc1752d8a25e918898dec44385721ed0a0a0fd41e9edeaa6394a4eb25637'
'SKIP'
'fd2b1a775271066e195fe55a89862ba65530457c4bb81404d0b510bce3c69b1c')
validpgpkeys=('3CE1780F78DD88DF45194FD706BC317B515ACE7C')
prepare(){
cd "${pkgname}-${pkgver}"
# Remove unneeded files
rm -rf resources/${pkgname}-portable.*
# fix freedom issues
rm -rf resources/images/mimetypes/{cbr,rar}.png
patch -fNp1 -i "$srcdir/libre.patch"
# Desktop integration (e.g. enforce arch defaults)
sed -e "/self.create_uninstaller()/,/os.rmdir(config_dir)/d" \
-e "/cc(\['xdg-desktop-menu', 'forceupdate'\])/d" \
-e "/cc(\['xdg-mime', 'install', MIME\])/d" \
-e "s/'ctc-posml'/'text' not in mt and 'pdf' not in mt and 'xhtml'/" \
-e "s/^Name=calibre/Name=Calibre/g" \
-i src/calibre/linux.py
}
build() {
cd "${pkgname}-${pkgver}"
LANG='en_US.UTF-8' python2 setup.py build
LANG='en_US.UTF-8' python2 setup.py gui
}
package() {
cd "${pkgname}-${pkgver}"
install -d "${pkgdir}/usr/share/zsh/site-functions" \
"${pkgdir}"/usr/share/{applications,desktop-directories,icons/hicolor}
install -Dm644 resources/calibre-mimetypes.xml \
"${pkgdir}/usr/share/mime/packages/calibre-mimetypes.xml"
XDG_DATA_DIRS="${pkgdir}/usr/share" LANG='en_US.UTF-8' \
python2 setup.py install --staging-root="${pkgdir}/usr" --prefix=/usr
cp -a man-pages/ "${pkgdir}/usr/share/man"
# Compiling bytecode FS#33392
python2 -m compileall "${pkgdir}/usr/lib/calibre/"
python2 -O -m compileall "${pkgdir}/usr/lib/calibre/"
}
|
