blob: e2010dbecb4d48cee9d80aaf3e2a6a8a3e95a300 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): mortzu <me@mortzu.de>
# Contributor (Arch): fnord0 <fnord0@riseup.net>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
_basekernel=4.15
_archrel=111
_parabolarel=1
pkgbase=acpi_call
pkgname=(acpi_call acpi_call-dkms)
pkgver=1.1.0
pkgrel=${_archrel}.parabola${_parabolarel}.basekernel${_basekernel}
pkgdesc="A linux kernel module that enables calls to ACPI methods through /proc/acpi/call (built for the linux-libre kernel package)"
arch=('i686' 'x86_64' 'armv7h')
url="http://github.com/mkottman/${pkgbase}"
license=('GPL')
# Generic (you shouldn't have to modify any of these variables)
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
makedepends=("linux-libre-headers>=${_basekernel}" "linux-libre-headers<${_toohigh}" "linux-libre>=${_basekernel}" "linux-libre<${_toohigh}")
makedepends+=('libelf')
_extramodules=extramodules-${_basekernel}
source=("${pkgbase}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
'dkms.conf')
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0'
'32e6ea6523b13132c6c7838bba7fbf3d040ba2d35a892c2c356245612720df8a')
prepare() {
cd $pkgbase-$pkgver
# Fix build with Linux-libre >= 3.17-gnu
sed -i 's|acpi/acpi.h|linux/acpi.h|' acpi_call.c
# Fix build with Linux-libre >= 4.12-gnu
sed -i 's|asm/uaccess.h|linux/uaccess.h|' acpi_call.c
}
build() {
cd $pkgbase-$pkgver
make KVERSION="$(cat /usr/lib/modules/$_extramodules/version)"
}
package_acpi_call() {
depends=("linux-libre>=${_basekernel}" "linux-libre<${_toohigh}")
replaces=("${pkgbase}-libre" "${pkgbase}-parabola")
conflicts=("${pkgbase}-libre" "${pkgbase}-parabola")
cd $pkgbase-$pkgver
install -Dt "$pkgdir/usr/lib/modules/$_extramodules" -m644 *.ko
find "$pkgdir" -name '*.ko' -exec xz {} +
echo acpi_call | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/acpi_call.conf"
mkdir -p "$pkgdir/usr/share/acpi_call"
cp -t "$pkgdir/usr/share/acpi_call" -dr --no-preserve=ownership examples support
}
package_acpi_call-dkms() {
depends=(dkms)
provides=("acpi_call=$pkgver-$pkgrel")
conflicts=(acpi_call)
cd $pkgbase-$pkgver
install -Dt "$pkgdir/usr/src/$pkgbase-$pkgver" -m644 Makefile acpi_call.c ../dkms.conf
echo acpi_call | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/acpi_call.conf"
mkdir -p "$pkgdir/usr/share/acpi_call"
cp -t "$pkgdir/usr/share/acpi_call" -dr --no-preserve=ownership examples support
}
# vim:set ts=2 sw=2 et:
|
