blob: 5b24a2801e5ccba7701df7fc82a778b70d999629 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 106771 2014-03-07 14:36:15Z bpiotrowski $
# Maintainer: Maxime Gauduin <alucryd@gmail.com>
# Contributor: mortzu <me@mortzu.de>
# Contributor: fnord0 <fnord0@riseup.net>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
_pkgname=acpi_call-lts
pkgname=acpi_call-libre-lts
pkgver=1.1.0
pkgrel=4
_extramodules=extramodules-3.10-LIBRE-LTS
pkgdesc='A linux kernel module that enables calls to ACPI methods through /proc/acpi/call (built for the linux-libre-lts kernel package)'
arch=('i686' 'x86_64')
url="http://github.com/mkottman/${_pkgname%-*}"
license=('GPL')
depends=('linux-libre-lts>=3.10.26')
makedepends=('linux-libre-lts-headers>=3.10.26')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname%-*}" "${_pkgname}=${pkgver}")
install="${_pkgname%-*}.install"
source=("${url}/archive/v${pkgver}.tar.gz")
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0')
build() {
cd ${_pkgname%-*}-${pkgver}
_kernver="$(cat /usr/lib/modules/${_extramodules}/version)"
make KVERSION="${_kernver}"
}
package() {
cd ${_pkgname%-*}-${pkgver}
install -dm 755 "${pkgdir}"/usr/lib/{modules/${_extramodules},modules-load.d}
install -m 644 ${_pkgname%-*}.ko "${pkgdir}"/usr/lib/modules/${_extramodules}/
gzip "${pkgdir}"/usr/lib/modules/${_extramodules}/${_pkgname%-*}.ko
echo ${_pkgname%-*} > "${pkgdir}"/usr/lib/modules-load.d/${_pkgname}.conf
install -dm 755 "${pkgdir}"/usr/share/${_pkgname}
cp -dr --no-preserve='ownership' {examples,support} "${pkgdir}"/usr/share/${_pkgname}/
}
# vim: ts=2 sw=2 et:
|
