2 files changed, 74 insertions, 0 deletions
diff --git a/pcr/lib32-pciutils/PKGBUILD b/pcr/lib32-pciutils/PKGBUILD
new file mode 100644
index 000000000..3a6304885
--- /dev/null
+++ b/pcr/lib32-pciutils/PKGBUILD
@@ -0,0 +1,36 @@
+# $Id$
+# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
+# Maintainer (Arch pciutils): Tobias Powalowski <tpowa@archlinux.org>
+_pkgname=pciutils
+pkgname=lib32-$_pkgname
+pkgver=3.3.0
+pkgrel=1
+pkgdesc="PCI bus configuration space access library (32 bit)"
+arch=(x86_64)
+license=('GPL2')
+#groups=('base')
+url="http://mj.ucw.cz/sw/pciutils/"
+depends=('glibc' 'hwids' 'kmod' "$_pkgname")
+source=(#ftp://ftp.kernel.org/pub/software/utils/${_pkgname}/${_pkgname}-${pkgver}.tar.bz2
+       ftp://atrey.karlin.mff.cuni.cz/pub/linux/pci/${_pkgname}-${pkgver}.tar.gz)
+md5sums=('b73bca5b1c2fd20a17a19f5040411521')
+
+options=(staticlibs)
+
+build() {
+  export CC='gcc -m32'
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+  
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  make OPT="${CFLAGS} -fPIC -DPIC" ZLIB=no SHARED=no PREFIX=/usr LIBDIR=/usr/lib32 SHAREDIR=/usr/share/hwdata MANDIR=/usr/share/man SBINDIR=/usr/bin lib/libpci.a 
+  cp lib/libpci.a "${srcdir}/"
+  make clean
+  make OPT="${CFLAGS}" ZLIB=no SHARED=yes PREFIX=/usr LIBDIR=/usr/lib32 SBINDIR=/usr/bin SHAREDIR=/usr/share/hwdata MANDIR=/usr/share/man all
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  make SHARED=yes PREFIX=/usr LIBDIR=/usr/lib32 SBINDIR=/usr/bin SHAREDIR=/usr/share/hwdata MANDIR=/usr/share/man DESTDIR="${pkgdir}" install-lib
+  install -m644 "${srcdir}/libpci.a" "${pkgdir}/usr/lib32/"
+  rm -rf "$pkgdir/usr/include"
+}
diff --git a/pcr/pciutils-staticlibs/PKGBUILD b/pcr/pciutils-staticlibs/PKGBUILD
new file mode 100644
index 000000000..5b52f41e1
--- /dev/null
+++ b/pcr/pciutils-staticlibs/PKGBUILD
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
+# Maintainer (Arch pcutils): Tobias Powalowski <tpowa@archlinux.org>
+pkgname=pciutils
+pkgver=3.3.0
+pkgrel=1
+pkgdesc="PCI bus configuration space access library and tools"
+arch=(i686 x86_64)
+license=('GPL2')
+#groups=('base')
+url="http://mj.ucw.cz/sw/pciutils/"
+depends=('glibc' 'hwids' 'kmod')
+source=(#ftp://ftp.kernel.org/pub/software/utils/${pkgname}/${pkgname}-${pkgver}.tar.bz2
+       ftp://atrey.karlin.mff.cuni.cz/pub/linux/pci/${pkgname}-${pkgver}.tar.gz)
+md5sums=('b73bca5b1c2fd20a17a19f5040411521')
+
+options=(staticlibs)
+_pkgname=$pkgname
+pkgname+='-staticlibs'
+pkgdesc+=" (build with options=(staticlibs))"
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  make OPT="${CFLAGS} -fPIC -DPIC" ZLIB=no SHARED=no PREFIX=/usr SHAREDIR=/usr/share/hwdata MANDIR=/usr/share/man SBINDIR=/usr/bin lib/libpci.a 
+  cp lib/libpci.a "${srcdir}/"
+  make clean
+  make OPT="${CFLAGS}" ZLIB=no SHARED=yes PREFIX=/usr SBINDIR=/usr/bin SHAREDIR=/usr/share/hwdata MANDIR=/usr/share/man all
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  make SHARED=yes PREFIX=/usr SBINDIR=/usr/bin SHAREDIR=/usr/share/hwdata MANDIR=/usr/share/man DESTDIR="${pkgdir}" install install-lib
+  install -m644 "${srcdir}/libpci.a" "${pkgdir}/usr/lib/"
+  # this is now supplied by the hwids package
+  rm -rf $pkgdir/usr/{sbin/update-pciids,share/{man/man8/update-pciids.8,hwdata}}
+}