1 files changed, 54 insertions, 0 deletions
diff --git a/pcr/mobile-broadband-provider-info/PKGBUILD b/pcr/mobile-broadband-provider-info/PKGBUILD
new file mode 100644
index 000000000..5047c0578
--- /dev/null
+++ b/pcr/mobile-broadband-provider-info/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer (Arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
+# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
+# Maintainers: Parabola hackers <dev@lists.parabola.nu>
+
+# This package is in Parabola only for architectures that don't have
+# mobile-broadband-provider-info in their feed. Here is the status of
+# mobile-broadband-provider-info in the various upstream GNU/Linux
+# distributions Parabola is based on:
+# +--------------+----------------+---------------+
+# | Architecture | Upstream       | Upstream repo |
+# +--------------+----------------+---------------+
+# | armv7h       | Arch Linux ARM | None          |
+# | i686         | Arch Linux 32  | community     |
+# | x86_64       | Arch Linux     | community     |
+# +--------------+----------------+---------------+
+
+pkgname=mobile-broadband-provider-info
+pkgver=20220511
+pkgrel=1
+pkgdesc="Network Management daemon"
+url="https://gitlab.gnome.org/GNOME/mobile-broadband-provider-info"
+arch=('armv7h')
+license=(custom)
+makedepends=(git libxslt)
+_commit=3d5c8d0f7e0264768a2c000d0fd4b4d4a991e041  # tags/20220511^0
+source=("git+https://gitlab.gnome.org/GNOME/mobile-broadband-provider-info.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
+}