1 files changed, 39 insertions, 0 deletions
diff --git a/pcr/java-commons-lang/PKGBUILD b/pcr/java-commons-lang/PKGBUILD
new file mode 100644
index 000000000..6f1c67ae3
--- /dev/null
+++ b/pcr/java-commons-lang/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+
+_pkgname=commons-lang
+pkgname=java-${_pkgname}
+pkgver=2.6
+pkgrel=1
+pkgdesc="Commons Lang - an extension of the java.lang package"
+arch=('any')
+url="https://commons.apache.org/lang/"
+license=('APACHE')
+depends=('java-runtime')
+makedepends=('apache-ant' 'jh')
+source=("https://archive.apache.org/dist/commons/lang/source/${_pkgname}-${pkgver}-src.tar.gz")
+md5sums=('37ee469f4caff6cfa28f9d0a0be2d4d2')
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}-src"
+  ant jar javadoc
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}-${pkgver}-src"
+
+  # Install license file
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+
+  # Install documentation
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -r "target/apidocs" "${pkgdir}/usr/share/doc/${pkgname}"
+
+  # Install Maven artifacts
+  export DESTDIR=${pkgdir}
+  jh mvn-install ${_pkgname} ${_pkgname} ${pkgver} \
+    "${srcdir}/${_pkgname}-${pkgver}-src/pom.xml" \
+    "${srcdir}/${_pkgname}-${pkgver}-src/target/${_pkgname}-${pkgver}.jar" \
+    "${_pkgname}.jar"
+  ln -s "/usr/share/java/${_pkgname}.jar" \
+    "${pkgdir}/usr/share/java/${_pkgname}-${pkgver}.jar"
+}
+\ No newline at end of file