1 files changed, 76 insertions, 0 deletions
diff --git a/nonsystemd/wireplumber/PKGBUILD b/nonsystemd/wireplumber/PKGBUILD
new file mode 100644
index 000000000..d63ef5724
--- /dev/null
+++ b/nonsystemd/wireplumber/PKGBUILD
@@ -0,0 +1,76 @@
+# Maintainer: David P. <megver83@parabola.nu>
+# Maintainer (Arch): David Runge <dvzrv@archlinux.org>
+# Maintainer (Arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
+
+pkgbase=wireplumber
+pkgname=(wireplumber wireplumber-docs)
+_commit=3400acd0db95fefdda7595d20466c095902d8997  # tags/0.4.10
+pkgver=0.4.10
+pkgrel=3
+pkgrel+=.nonsystemd1
+pkgdesc="Session / policy manager implementation for PipeWire"
+url="https://pipewire.pages.freedesktop.org/wireplumber/"
+arch=(x86_64)
+arch+=(i686 armv7h)
+license=(MIT)
+makedepends=(git meson doxygen graphviz 'pipewire>=0.3.43' glib2 lua
+             gobject-introspection python-sphinx python-sphinx_rtd_theme
+             python-breathe python-lxml elogind)
+depends=(libelogind)
+options=(debug)
+source=("$pkgbase::git+https://gitlab.freedesktop.org/pipewire/wireplumber.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  local meson_options=(
+    -D system-lua=true
+    -D systemd=disabled
+  )
+
+  arch-meson $pkgbase build "${meson_options[@]}"
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_wireplumber() {
+  depends=('pipewire>=0.3.43' lua libpipewire-0.3.so
+           libg{lib,module,object,io}-2.0.so)
+  optdepends=('wireplumber-docs: Documentation')
+  provides=(pipewire-session-manager libwireplumber-0.4.so)
+  conflicts=(pipewire-media-session)
+
+  meson install -C build --destdir "$pkgdir"
+
+  _pick docs "$pkgdir"/usr/share/doc
+
+  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 $pkgbase/{NEWS,README}*
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
+}
+
+package_wireplumber-docs() {
+  pkgdesc+=" - documentation"
+
+  mv docs/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgbase/LICENSE
+}
+
+# vim:set sw=2 et: