1 files changed, 56 insertions, 0 deletions
diff --git a/nonprism-testing/gnome-settings-daemon/PKGBUILD b/nonprism-testing/gnome-settings-daemon/PKGBUILD
new file mode 100644
index 000000000..c1347740b
--- /dev/null
+++ b/nonprism-testing/gnome-settings-daemon/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Maintainer: André Silva <emulatorman@parabola.nu>
+# Contributor: Isaac David <isacdaavid@at@isacdaavid.info>
+
+pkgname=gnome-settings-daemon
+pkgver=3.24.2
+pkgrel=1.nonprism1
+pkgdesc="GNOME Settings Daemon, without geoclue2 support"
+url="https://git.gnome.org/browse/gnome-settings-daemon"
+arch=(i686 x86_64 armv7h)
+license=(GPL)
+depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse libnotify libsystemd
+         libwacom pulseaudio pulseaudio-alsa upower librsvg libgweather geocode-glib nss
+         libgudev gtk3-print-backends libnm)
+makedepends=(intltool xf86-input-wacom libxslt docbook-xsl python git gnome-common)
+groups=(gnome)
+_commit=2ff67385f2b7c7adb0ab438cb41d114235a8e40a  # tags/GNOME_SETTINGS_DAEMON_3_24_2^0
+source=("git+https://git.gnome.org/browse/gnome-settings-daemon#commit=$_commit"
+        "git+https://git.gnome.org/browse/libgnome-volume-control"
+        nonprism.patch)
+sha256sums=('SKIP'
+            'SKIP'
+            '04217ba23fe3d76b04bdb92059257972ee7511aec6f713d807434f6a10e3d1a5')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_SETTINGS_DAEMON_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule."panels/media-keys/gvc".url "$srcdir/libgnome-volume-control"
+  git submodule update
+
+  patch -p1 -i $srcdir/nonprism.patch
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+      --libexecdir=/usr/lib/$pkgname --disable-static
+
+  #https://bugzilla.gnome.org/show_bug.cgi?id=656231
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}