1 files changed, 72 insertions, 0 deletions
diff --git a/nonprism-testing/gnome-online-accounts/PKGBUILD b/nonprism-testing/gnome-online-accounts/PKGBUILD
new file mode 100644
index 000000000..8981482bb
--- /dev/null
+++ b/nonprism-testing/gnome-online-accounts/PKGBUILD
@@ -0,0 +1,72 @@
+# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
+# Maintainer: Márcio Silva <coadde@parabola.nu>
+# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
+
+pkgname=gnome-online-accounts
+pkgver=3.24.1
+pkgrel=1.nonprism1
+pkgdesc="Single sign-on framework for GNOME, without support for unsafe and dangerous for privacy protocols"
+url="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+arch=(i686 x86_64)
+license=(LGPL)
+depends=(webkit2gtk json-glib libnotify rest libsecret telepathy-glib krb5 gcr)
+makedepends=(intltool gobject-introspection gtk-doc vala git gnome-common)
+conflicts=("${pkgname}-coherence" "${pkgname}-nonprism" )
+replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
+optdepends=('gvfs-goa: Virtual file systems (e.g. OwnCloud)')
+_commit=4f26391fc5b3d54cb73d9cd05599acec33d90928  # tags/3.24.1^0
+source=("git+https://git.gnome.org/browse/gnome-online-accounts#commit=$_commit"
+        "git+https://git.gnome.org/browse/telepathy-account-widgets")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.telepathy-account-widgets.url "$srcdir/telepathy-account-widgets"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+
+  ./configure \
+    --prefix=/usr \
+    --libexecdir=/usr/lib/$pkgname \
+    --disable-static \
+    --enable-gtk-doc \
+    --enable-media-server \
+    --enable-kerberos \
+    --enable-telepathy \
+    --enable-owncloud \
+    --enable-imap-smtp \
+    --disable-lastfm \
+    --disable-exchange \
+    --disable-facebook \
+    --disable-flickr \
+    --disable-google \
+    --disable-pocket \
+    --disable-windows-live \
+    --disable-twitter \
+    --disable-yahoo \
+    --disable-foursquare
+
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et: