nitrokey-app-git: add new package to [pcr] - Packaging request #1078 -> https://labs.parabola.nu/issues/1078

1 files changed, 38 insertions, 0 deletions

diff --git a/pcr/nitrokey-app-git/PKGBUILD b/pcr/nitrokey-app-git/PKGBUILD
new file mode 100644
index 000000000..507a1aab6
--- /dev/null
+++ b/pcr/nitrokey-app-git/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer (Arch): Christoph J. Thompson <thompsonc@protonmail.ch>
+
+_pkgname=nitrokey-app
+pkgname=nitrokey-app-git
+pkgver=r626.g3b9d633
+pkgrel=1
+pkgdesc="Nitrokey management application"
+arch=('i686' 'x86_64')
+url="https://www.nitrokey.com"
+license=('GPL3')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+depends=('qt5-base' 'libusb>=1.0.0')
+makedepends=('git' 'cmake')
+source=("${_pkgname}::git+https://github.com/Nitrokey/nitrokey-app")
+install=nitrokey-app.install
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgname}"
+  printf "r%s.g%s" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${_pkgname}"
+  sed -i 's|/etc/udev/rules.d|/usr/lib/udev/rules.d|g' CMakeLists.txt
+  sed -i 's|/etc/bash_completion.d|/usr/share/bash-completion/completions|g' \
+         CMakeLists.txt
+  cmake . -DCMAKE_INSTALL_PREFIX=/usr -DHAVE_LIBAPPINDICATOR=NO
+  make
+}
+
+package() {
+  cd "${_pkgname}"
+  make DESTDIR="${pkgdir}" install
+}