[jami-qt][jami-libclient][jami-daemon]: temporary blacklist replacements (x86_64 only)

3 files changed, 183 insertions, 0 deletions

diff --git a/libre/jami-daemon/PKGBUILD b/libre/jami-daemon/PKGBUILD
new file mode 100644
index 000000000..bf2ae2cb2
--- /dev/null
+++ b/libre/jami-daemon/PKGBUILD
@@ -0,0 +1,76 @@
+# Maintainer (arch): Bruno Pagani <archange@archlinux.org>
+# Contributor: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+
+# parabola changes and rationale:
+#  - no changes
+#  - temporary 'jami-qt' build without qt6-webengine
+#    the next jami release should have this VCS change;
+#    so the arch pckage will be FDSG-fit then
+#  - NOTE: this is built from VCS; but so was the
+#    latest arch package - AFAIK, this should be
+#    named 'jami-qt-git' - it is a one-time
+#    blacklist replacement though; so it is less
+#    troublesome to keep the arch pkgname
+#  - NOTE: jami-{daemon,libclient,qt} versions are all tightly coupled,
+#          even at the VCS level
+#          implied build order: jami-daemon <- jami-libclient <- jami-qt
+
+
+pkgname=jami-daemon
+pkgver=20220505
+pkgrel=1
+pkgrel+=.parabola1
+pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (daemon component)"
+arch=(x86_64)
+url="https://jami.net"
+license=(GPL3)
+groups=(jami)
+depends=(glibc opendht gnutls nettle libgit2 libsecp256k1 ffmpeg speexdsp
+         fmt yaml-cpp jsoncpp zlib dbus-c++ alsa-lib libpulse jack
+         libupnp libnatpmp openssl webrtc-audio-processing systemd-libs
+         libarchive)
+# portaudio needs a not-yet-upstream patch https://git.jami.net/savoirfairelinux/jami-daemon/-/issues/650
+makedepends=(git cmake perl asio msgpack-c msgpack-cxx restinio systemd meson)
+checkdepends=(cppunit)
+_commit=8750049b0ce58133b05c90330df6fd3464dadd1d
+_pjprojectver=e1f389d0b905011e0cb62cbdf7a8b37fc1bcde1a
+source=(git+https://git.jami.net/savoirfairelinux/${pkgname}.git#commit=${_commit}
+        https://github.com/savoirfairelinux/pjproject/archive/${_pjprojectver}/pjproject-${_pjprojectver}.tar.gz)
+noextract=(pjproject-${_pjprojectver}.tar.gz)
+sha512sums=(SKIP a1ed0519ddf8dc91f47042497530cbcb1c8736506d0c2b677751a3368c0a202952ff563946664705dbf5806bed8ade784885db62f8278a204f516a4e60917b1e)
+
+# pkgver() {
+#   cd ${pkgname}
+#   TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD
+# }
+
+prepare() {
+  cd ${pkgname}
+  cp ../pjproject-${_pjprojectver}.tar.gz contrib/tarballs
+  mkdir contrib/native
+}
+
+build() {
+  cd ${pkgname}/contrib/native
+  export CXXFLAGS+=' -fpermissive'
+  ../bootstrap \
+      --disable-downloads \
+      --disable-all \
+      --enable-pjproject
+  make DEPS_pjproject=
+
+  cd "${srcdir}"
+  arch-meson ${pkgname} build -D interfaces=library,dbus -D opensl=disabled -D portaudio=disabled \
+                              $( ((CHECKFUNC)) && echo -D tests=true) \
+                              -D pkg_config_path="${PWD}/${pkgname}/contrib/$(cc -dumpmachine)/lib/pkgconfig"
+  meson compile -C build
+}
+
+#check() {
+# https://git.jami.net/savoirfairelinux/jami-daemon/-/issues/649
+#  meson test -C build --print-errorlogs
+#}
+
+package() {
+  meson install -C build --destdir "${pkgdir}"
+}
diff --git a/libre/jami-libclient/PKGBUILD b/libre/jami-libclient/PKGBUILD
new file mode 100644
index 000000000..8e0ab74b5
--- /dev/null
+++ b/libre/jami-libclient/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer (arch): Bruno Pagani <archange@archlinux.org>
+# Contributor: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+
+
+# parabola changes and rationale:
+#  - no changes
+#  - temporary 'jami-qt' build without qt6-webengine
+#    the next jami release should have this VCS change;
+#    so the arch pckage will be FDSG-fit then
+#  - NOTE: this is built from VCS; but so was the
+#    latest arch package - AFAIK, this should be
+#    named 'jami-qt-git' - it is a one-time
+#    blacklist replacement though; so it is less
+#    troublesome to keep the arch pkgname
+#  - NOTE: jami-{daemon,libclient,qt} versions are all tightly coupled,
+#          even at the VCS level
+#          implied build order: jami-daemon <- jami-libclient <- jami-qt
+
+
+pkgname=jami-libclient
+pkgver=20220505
+pkgrel=1
+pkgrel+=.parabola1
+pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (client communication library)"
+arch=(x86_64)
+url="https://jami.net"
+license=(GPL3)
+groups=(jami)
+depends=(jami-daemon qt6-base)
+makedepends=(git cmake qt6-tools)
+provides=(libjamiclient)
+conflicts=(libjamiclient)
+replaces=(libjamiclient)
+_commit=c5bca2933fb02ef7f81e8fe0772801a4f97fd1f5
+source=(git+https://git.jami.net/savoirfairelinux/jami-libclient.git#commit=${_commit})
+md5sums=(SKIP)
+
+# pkgver() {
+#   cd ${pkgname}
+#   TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD
+# }
+
+build() {
+  cmake -B build -S jami-libclient \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release
+  make -C build
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" install
+}
diff --git a/libre/jami-qt/PKGBUILD b/libre/jami-qt/PKGBUILD
new file mode 100644
index 000000000..abccb3a36
--- /dev/null
+++ b/libre/jami-qt/PKGBUILD
@@ -0,0 +1,55 @@
+# Maintainer (arch): Bruno Pagani <archange@archlinux.org>
+
+
+# parabola changes and rationale:
+#  - no changes
+#  - temporary 'jami-qt' build without qt6-webengine
+#    the next jami release should have this VCS change;
+#    so the arch pckage will be FDSG-fit then
+#  - NOTE: this is built from VCS; but so was the
+#    latest arch package - AFAIK, this should be
+#    named 'jami-qt-git' - it is a one-time
+#    blacklist replacement though; so it is less
+#    troublesome to keep the arch pkgname
+#  - NOTE: jami-{daemon,libclient,qt} versions are all tightly coupled,
+#          even at the VCS level
+#          implied build order: jami-daemon <- jami-libclient <- jami-qt
+
+
+pkgname=jami-qt
+pkgver=20220505
+pkgrel=1
+pkgrel+=.parabola1
+pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (Qt client)"
+arch=(x86_64)
+url="https://jami.net"
+license=(GPL3)
+groups=(jami)
+depends=(jami-libclient glib2 gdk-pixbuf2 libnm libnotify qrencode
+         qt6-declarative qt6-multimedia qt6-networkauth qt6-svg
+         qt6-5compat qt6-webengine qt6-webchannel)
+depends=( ${depends[*]/qt6-webengine/} )
+makedepends=(git cmake python qt6-tools)
+replaces=(jami-gnome)
+conflicts=(jami-gnome)
+_commit=dd0dc87a0110b55f7f5ee450e13520c683e78650
+source=(git+https://git.jami.net/savoirfairelinux/jami-client-qt.git#commit=${_commit})
+md5sums=(SKIP)
+
+# pkgver() {
+#   cd jami-client-qt
+#   TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD
+# }
+
+build() {
+  cmake -B build -S jami-client-qt \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DWITH_WEBENGINE=false \
+    -Wno-dev
+  make -C build
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" install
+}