libre/marble: added marble-common without qt5-webengine dependency

1 files changed, 62 insertions, 0 deletions

diff --git a/libre/marble/PKGBUILD b/libre/marble/PKGBUILD
new file mode 100644
index 000000000..682a9bc4e
--- /dev/null
+++ b/libre/marble/PKGBUILD
@@ -0,0 +1,62 @@
+# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
+# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
+# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
+# Contributor (Arch): Gustavo Alvarez <sl1pkn07@gmail.com>
+# Contributor (Arch): Balló György <ballogyor+arch at gmail dot com>
+
+pkgbase=marble
+pkgname=(marble-common)
+pkgver=18.12.2
+pkgrel=1
+pkgrel+=.parabola1
+pkgdesc="Desktop Globe"
+arch=(x86_64)
+arch+=(i686 armv7h)
+url="https://www.kde.org/applications/system/marble"
+license=(GPL)
+makedepends=(extra-cmake-modules gpsd kdoctools knewstuff kparts krunner libwlocate phonon-qt5
+             plasma-workspace qt5-serialport qt5-tools qt5-webkit shapelib)
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgbase-$pkgver.tar.xz"{,.sig})
+sha256sums=('3b099da5017fe505e8a8d058e323f08ecabdb8b2c6e6a49538c60ed52285e3f7'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_SYSCONFDIR=/etc \
+    -DQT_PLUGINS_DIR=lib/qt/plugins \
+    -DBUILD_TESTING=OFF \
+    -DBUILD_MARBLE_EXAMPLES=OFF \
+    -DBUILD_MARBLE_TESTS=OFF \
+    -DMOBILE=OFF
+  make
+}
+
+package_marble-common() {
+  pkgdesc='Common libraries and plugins for Marble'
+  depends=(qt5-svg qt5-webkit phonon-qt5 desktop-file-utils)
+  optdepends=('gpsd: GPS based geolocation'
+              'libwlocate: WLAN based geolocation'
+              'qt5-serialport: APRS plugin'
+              'shapelib: SHP plugin')
+  conflicts=(marble-data)
+  replaces=(marble-data libastro)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+  rm -rf "$pkgdir"/usr/share/{config.kcfg,kxmlgui5,metainfo,plasma} \
+         "$pkgdir"/usr/bin \
+         "$pkgdir"/etc \
+         "$pkgdir"/usr/lib/qt/{qml,plugins/*.so} \
+         "$pkgdir"/usr/share/applications/{marble_geo.desktop,marble_worldwind.desktop,org.kde.marble*.desktop} \
+         "$pkgdir"/usr/share/kservices5/{marble_part.desktop,plasma*} \
+         "$pkgdir"/usr/share/locale/*/LC_MESSAGES/*.mo
+}