avidemux 2.6.14-1.parabola1: updating version

1 files changed, 39 insertions, 106 deletions

diff --git a/libre/avidemux/PKGBUILD b/libre/avidemux/PKGBUILD
index 0595d695b..f6155dacf 100644
--- a/libre/avidemux/PKGBUILD
+++ b/libre/avidemux/PKGBUILD
@@ -1,137 +1,70 @@
-# $Id: PKGBUILD 273049 2016-08-04 20:59:53Z bpiotrowski $
+# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
 # Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
 # Maintainer: André Silva <emulatorman@parabola.nu>
 
 pkgbase=avidemux
-pkgname=('avidemux-cli' 'avidemux-gtk' 'avidemux-qt')
-pkgver=2.5.6
-pkgrel=15.parabola1
+pkgname=('avidemux-cli' 'avidemux-qt')
+pkgver=2.6.14
+pkgrel=1.parabola1
+pkgdesc='Graphical tool to edit video (filter/re-encode/split), without nonfree faac support'
+url='http://fixounet.free.fr/avidemux/'
 arch=('i686' 'x86_64')
-license=('GPL')
-url="http://fixounet.free.fr/avidemux/"
-makedepends=('cmake' 'libxslt' 'gtk2' 'qt4' 'jack' 'libvorbis' 'sdl' 'libxv'
-             'alsa-lib' 'lame' 'xvidcore' 'faad2' 'libx264' 'libsamplerate'
-             'opencore-amr' 'yasm' 'mesa' 'libvpx' 'libpulse' 'libva')
-options=('!makeflags' '!emptydirs')
-source=(http://downloads.sourceforge.net/avidemux/avidemux_${pkgver}.tar.gz
-        mangled-variables-used-attribute.patch
-        buildfix.patch)
-sha1sums=('47205c236bf6a4435b9d4dd944493c7b7e2752f5'
-          'da66b69593da62373f2309f88a284145fbfd99ac'
-          '8b4b45627a8ed4409e32ac2ece361a0cf935e9d4')
+license=('GPL2')
+makedepends=('cmake' 'libxslt' 'qt5-base' 'jack' 'libvorbis' 'libxv' 'opus' 'desktop-file-utils'
+             'alsa-lib' 'lame' 'xvidcore' 'faad2' 'x264' 'libx264' 'x265' 'libsamplerate'
+             'opencore-amr' 'yasm' 'mesa' 'libvpx' 'libpulse' 'libva' 'intltool' 'sqlite'
+             'libvdpau' 'libdca' 'fribidi' 'glu' 'qt5-tools' 'pkg-config')
+options=('!emptydirs')
+source=(https://downloads.sourceforge.net/avidemux/avidemux_${pkgver}.tar.gz)
+sha512sums=('c940850df93e77b3176850cfdd7851c1e133835802a2bc979a497d825d85ca2fd394e2dc813242b9009f1b6ec2904f63163bd9afda9478be064518e4572449a1')
 
 prepare() {
   cd ${pkgbase}_${pkgver}
-
-  # Fix build on i686 when using GCC 5.1
-  # https://bugs.archlinux.org/task/45361
-  patch -Np1 -i ../mangled-variables-used-attribute.patch
-
-  # Fix build with gcc 6.1 and libvpx 1.6.0
-  patch -Np1 -i ../buildfix.patch
+  sed -i 's|../avidemux/qt4|../avidemux/qt4 -DLRELEASE_EXECUTABLE=/usr/bin/lrelease-qt5|' bootStrap.bash
 }
 
 build() {
   cd ${pkgbase}_${pkgver}
-  mkdir build
-  cd build
-  cmake -D CMAKE_INSTALL_PREFIX=/usr -D CMAKE_BUILD_TYPE=Release \
-    -D CMAKE_SKIP_RPATH=ON -D GTK=1 -D QT4=1 \
-    -D LRELEASE_EXECUTABLE=/usr/lib/qt4/bin/lrelease ..
-  make
-
-# plugin build expects libraries to be already installed; we fake a prefix
-# in build/ by symlinking all libraries to build/lib/
-  cd lib
-  find ../avidemux -name '*.so*' | xargs ln -sft .
-  cd ../../plugins
-  mkdir build
-  cd build
-  cmake -D CMAKE_INSTALL_PREFIX=/usr -D AVIDEMUX_SOURCE_DIR="${srcdir}/avidemux_${pkgver}" \
-    -D AVIDEMUX_CORECONFIG_DIR="${srcdir}/avidemux_${pkgver}/build/config" \
-    -D AVIDEMUX_INSTALL_PREFIX="${srcdir}/avidemux_${pkgver}/build" \
-    -D CMAKE_BUILD_TYPE=Release -D CMAKE_SKIP_RPATH=ON ..
-  make
+  bash bootStrap.bash --with-core --with-cli --with-plugins
 }
 
 package_avidemux-cli() {
-  pkgdesc="A graphical tool to edit video (filter/re-encode/split), without nonfree faac support"
-  depends=('libxml2' 'sdl' 'fontconfig' 'libvpx' 'libva')
+  depends=('libxml2' 'fontconfig' 'libvpx' 'libva' 'sqlite')
   optdepends=('lame: for the corresponding audio encoder plugin'
               'faad2: for the corresponding audio decoder plugin'
+              'opus: for the corresponding audio decoder plugin'
               'opencore-amr: for the corresponding audio decoder plugin'
               'jack: for the corresponding audio device plugin'
               'libpulse: for the corresponding audio device plugin'
-              'sdl: for the corresponding audio device plugin'
+              'x264: for the corresponding video encoder plugin'
               'libx264: for the corresponding video encoder plugin'
-              'xvidcore: for the corresponding video encoder plugin')
-  provides=('avidemux')
-  conflicts=('avidemux' 'avidemux-libre-cli' 'avidemux-cli-parabola')
-  replaces=('avidemux' 'avidemux-libre-cli' 'avidemux-cli-parabola')
-
-  cd ${pkgbase}_${pkgver}/build
-  make DESTDIR="${pkgdir}" install
-
-  cd "${srcdir}/${pkgbase}_${pkgver}/plugins/build"
-  make DESTDIR="${pkgdir}" install
-  rm -r "${pkgdir}"/usr/share/avidemux
-  rm "${pkgdir}"/usr/share/ADM_addons/avsfilter/{avsload.exe,pipe_source.dll}
-  rm "${pkgdir}"/usr/bin/avidemux2_{gtk,qt4}
-  rm "${pkgdir}"/usr/lib/*{_gtk,_qt4,Gtk,QT4}.so
-  rm "${pkgdir}"/usr/lib/ADM_plugins/videoEncoder/x264/*{Gtk,Qt}.so
-  rm "${pkgdir}"/usr/lib/ADM_plugins/videoEncoder/xvid/*{Gtk,Qt}.so
-  rm "${pkgdir}"/usr/lib/ADM_plugins/videoFilter/*{_gtk,_qt4}.so
-
-  ln -s /usr/lib/ADM_plugins/videoEncoder/libADM_vidEnc_xvid.so "${pkgdir}/usr/lib/libADM_vidEnc_xvid.so"
-  ln -s /usr/lib/ADM_plugins/videoEncoder/libADM_vidEnc_x264.so "${pkgdir}/usr/lib/libADM_vidEnc_x264.so"
-
-  install -D -m644 ../../avidemux_icon.png "${pkgdir}/usr/share/pixmaps/avidemux.png"
-  install -D -m644 ../../man/avidemux.1 "${pkgdir}/usr/share/man/man1/avidemux.1"
-}
-
-package_avidemux-gtk() {
-  pkgdesc="A graphical tool to edit video (filter/re-encode/split) - GTK GUI, without nonfree faac support"
-  depends=("avidemux-cli=${pkgver}" 'gtk2' 'libxv' 'desktop-file-utils')
-  replaces=('avidemux-libre-gtk' 'avidemux-gtk-parabola')
-  conflicts=('avidemux-libre-gtk' 'avidemux-gtk-parabola')
-  install=avidemux.install
+              'x265: for the corresponding video encoder plugin'
+              'xvidcore: for the corresponding video encoder plugin'
+              'qt5-base: for the QtScript scripting support'
+              'libdca: for the corresponding audio decoder plugin'
+              'fribidi: for the corresponding video filter plugin')
 
   cd ${pkgbase}_${pkgver}
-  install -D -m755 build/avidemux/avidemux2_gtk "${pkgdir}/usr/bin/avidemux2_gtk"
-
-  install -d "${pkgdir}"/usr/lib/ADM_plugins/videoEncoder/{x264,xvid}
-  install -d "${pkgdir}"/usr/lib/ADM_plugins/videoFilter
-
-  install -D -m755 build/lib/*{_gtk,Gtk}.so "${pkgdir}/usr/lib"
-  install -D -m755 plugins/build/ADM_videoEncoder/ADM_vidEnc_x264/gtk/*Gtk.so "${pkgdir}/usr/lib/ADM_plugins/videoEncoder/x264"
-  install -D -m755 plugins/build/ADM_videoEncoder/ADM_vidEnc_xvid/gtk/*Gtk.so "${pkgdir}/usr/lib/ADM_plugins/videoEncoder/xvid"
-  install -D -m755 plugins/build/ADM_videoFilters/*/*_gtk.so "${pkgdir}/usr/lib/ADM_plugins/videoFilter"
+  (cd buildCli; make DESTDIR="${pkgdir}" install)
+  (cd buildCore; make DESTDIR="${pkgdir}" install)
+  (cd buildPluginsCLI; make DESTDIR="${pkgdir}" install)
+  (cd buildPluginsCommon; make DESTDIR="${pkgdir}" install)
 
-  install -D -m644 avidemux2-gtk.desktop "${pkgdir}/usr/share/applications/avidemux-gtk.desktop"
-  sed -i "s|\[\$e\]||" "${pkgdir}/usr/share/applications/avidemux-gtk.desktop"
+  install -Dm 644 avidemux_icon.png "${pkgdir}/usr/share/pixmaps/avidemux.png"
+  install -Dm 644 man/avidemux.1 "${pkgdir}/usr/share/man/man1/avidemux.1"
 }
 
 package_avidemux-qt() {
-  pkgdesc="A graphical tool to edit video (filter/re-encode/split) - Qt GUI, without nonfree faac support"
-  depends=("avidemux-cli=${pkgver}" 'qt4')
-  replaces=('avidemux-libre-qt' 'avidemux-qt-parabola')
-  conflicts=('avidemux-libre-qt' 'avidemux-qt-parabola')
-  install=avidemux.install
+  pkgdesc='Graphical tool to edit video (filter/re-encode/split) - Qt GUI, without nonfree faac support'
+  depends=("avidemux-cli=${pkgver}" 'qt5-base' 'x264' 'x265' 'libx264' 'glu' 'libxv' 'desktop-file-utils')
+  replaces=('avidemux-gtk')
 
   cd ${pkgbase}_${pkgver}
-  install -D -m755 build/avidemux/avidemux2_qt4 "${pkgdir}/usr/bin/avidemux2_qt4"
-  install -d "${pkgdir}"/usr/lib/ADM_plugins/videoEncoder/{x264,xvid}
-  install -d "${pkgdir}"/usr/lib/ADM_plugins/videoFilter
+  (cd buildQt5; make DESTDIR="${pkgdir}" install)
+  (cd buildPluginsQt5; make DESTDIR="${pkgdir}" install)
 
-  install -D -m755 build/lib/*{_qt4,QT4}.so "${pkgdir}/usr/lib"
-  install -D -m755 plugins/build/ADM_videoEncoder/ADM_vidEnc_x264/qt4/*Qt.so "${pkgdir}/usr/lib/ADM_plugins/videoEncoder/x264"
-  install -D -m755 plugins/build/ADM_videoEncoder/ADM_vidEnc_xvid/qt4/*Qt.so "${pkgdir}/usr/lib/ADM_plugins/videoEncoder/xvid"
-  install -D -m755 plugins/build/ADM_videoFilters/*/*_qt4.so "${pkgdir}/usr/lib/ADM_plugins/videoFilter"
-
-  install -d "${pkgdir}/usr/share/avidemux/i18n"
-  install -D -m644 build/po/*.qm "${pkgdir}/usr/share/avidemux/i18n"
-
-  install -D -m644 avidemux2.desktop "${pkgdir}/usr/share/applications/avidemux-qt.desktop"
-  sed -i 's/Name=avidemux2/Name=avidemux (Qt)/' "${pkgdir}/usr/share/applications/avidemux-qt.desktop"
-  sed -i 's/avidemux2_gtk/avidemux2_qt4/' "${pkgdir}/usr/share/applications/avidemux-qt.desktop"
+  install -Dm 644 avidemux2.desktop "${pkgdir}/usr/share/applications/avidemux-qt.desktop"
+  sed -i 's|gtk|qt5|' "${pkgdir}/usr/share/applications/avidemux-qt.desktop"
 }
+
+# vim: ts=2 sw=2 et: