Merge remote-tracking branch 'users/niitotantei/master'

2 files changed, 65 insertions, 0 deletions

diff --git a/pcr/smartypants/PKGBUILD b/pcr/smartypants/PKGBUILD
new file mode 100644
index 000000000..c803986e8
--- /dev/null
+++ b/pcr/smartypants/PKGBUILD
@@ -0,0 +1,30 @@
+# Contributor: Daniel Milewski <niitotantei@riseup.net>
+
+pkgname=smartypants
+pkgver=1.5.1
+pkgrel=1
+pkgdesc='Smart punctuation for web sites'
+arch=(any)
+url=http://daringfireball.net/projects/smartypants/
+license=(BSD3)
+depends=(perl)
+makedepends=(unzip)
+source=(http://daringfireball.net/projects/downloads/SmartyPants_$pkgver.zip)
+sha256sums=(2813a12d8dd23f091399195edd7965e130103e439e2a14f298b75b253616d531)
+
+build()
+{
+  cd "$srcdir/SmartyPants_$pkgver"
+
+  pod2man SmartyPants.pl > smartypants.1
+  sed -n '/^Copyright (c)/,/damage\./p' 'SmartyPants Readme.txt' > LICENSE
+}
+
+package()
+{
+  cd "$srcdir/SmartyPants_$pkgver"
+
+  install -Dm 755 SmartyPants.pl "$pkgdir/usr/bin/smartypants"
+  install -Dm 644 smartypants.1 "$pkgdir/usr/share/man/man1/smartypants.1"
+  install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
diff --git a/pcr/vim-autotag/PKGBUILD b/pcr/vim-autotag/PKGBUILD
new file mode 100644
index 000000000..6c53c0e7d
--- /dev/null
+++ b/pcr/vim-autotag/PKGBUILD
@@ -0,0 +1,35 @@
+# Contributor: Daniel Milewski <niitotantei@riseup.net>
+
+pkgname=vim-autotag
+pkgver=r5.433b6b5
+_gitcommit=433b6b5be330615c4cb97ec748a773115dcced60
+pkgrel=1
+pkgdesc='Automatically discover and "properly" update ctags files on save'
+arch=(any)
+url=https://github.com/craigemery/vim-autotag
+license=(custom:vim)
+groups=(vim-plugins)
+mkdepends=(git)
+depends=(ctags vim)
+mksource=($pkgname-$pkgver::git+https://github.com/craigemery/$pkgname.git#commit=$_gitcommit)
+source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz)
+mksha256sums=(SKIP)
+sha256sums=(3fe4270ec84a4299866c6c205a9869055a72194c6482fed7a7c4bb99acc5b5b0)
+
+mksource()
+{
+  cd "$srcdir/$pkgname-$pkgver"
+
+  rm .gitignore
+}
+
+package()
+{
+  cd "$srcdir/$pkgname-$pkgver"
+
+  install -Dm 644 plugin/autotag.py "$pkgdir/usr/share/vim/vimfiles/plugin/autotag.py"
+  install -Dm 644 plugin/autotag.vim "$pkgdir/usr/share/vim/vimfiles/plugin/autotag.vim"
+
+  install -d "$pkgdir/usr/share/licenses/$pkgname"
+  ln -s /usr/share/licenses/vim-runtime/license.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}