blob: d93ac31b4a0e0d7dc2a955f6e001c6c7e9731dd5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
#
# Maintainer (Arch): Iacopo Isimbaldi <isiachi@rhye.it>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
#
pkgbase="zfs-dkms"
pkgname=("zfs-dkms" "zfs-utils")
pkgver=0.6.5.8
pkgrel=2
license=('CDDL')
makedepends=("git" "spl-dkms=${pkgver}")
arch=("i686" "x86_64")
url="http://zfsonlinux.org/"
source=("git+https://github.com/zfsonlinux/zfs.git#tag=zfs-${pkgver}"
"zfs.bash-completion-r1"
"zfs.initcpio.install"
"zfs.initcpio.hook")
sha256sums=('SKIP'
'b60214f70ffffb62ffe489cbfabd2e069d14ed2a391fac0e36f914238394b540'
'17114052aa20c528f022f7f1349971aa28810e2ed2c97871226b5679a91f7e77'
'90d50df503464e8d76770488dbd491cb633ee27984d4d3a31b03f1a4e7492038')
build() {
cd "${srcdir}/zfs"
./autogen.sh
./configure --prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--with-mounthelperdir=/usr/bin \
--libdir=/usr/lib \
--datadir=/usr/share \
--includedir=/usr/include \
--with-udevdir=/usr/lib/udev \
--libexecdir=/usr/lib/zfs \
--with-config=user
make
}
package_zfs-dkms() {
pkgdesc="Kernel modules for the Zettabyte File System."
depends=("spl-dkms=${pkgver}" "zfs-utils=${pkgver}-${pkgrel}" "dkms")
provides=("zfs")
conflicts=("zfs-git" "zfs-lts")
dkmsdir="${pkgdir}/usr/src/zfs-${pkgver}"
install -d "${dkmsdir}"
cp -a ${srcdir}/zfs/. ${dkmsdir}
cd "${dkmsdir}"
make clean
make distclean
find . -name ".git*" -print0 | xargs -0 rm -fr --
scripts/dkms.mkconf -v ${pkgver} -f dkms.conf -n zfs
chmod g-w,o-w -R .
}
package_zfs-utils() {
pkgdesc="Kernel module support files for the Zettabyte File System."
conflicts=("zfs-utils-git" "zfs-utils-lts")
cd "${srcdir}/zfs"
make DESTDIR="${pkgdir}" install
# Remove uneeded files
rm -r "${pkgdir}"/etc/init.d
rm -r "${pkgdir}"/usr/lib/dracut
rm -r "${pkgdir}"/usr/share/initramfs-tools
install -D -m644 "${srcdir}"/zfs.initcpio.hook "${pkgdir}"/usr/lib/initcpio/hooks/zfs
install -D -m644 "${srcdir}"/zfs.initcpio.install "${pkgdir}"/usr/lib/initcpio/install/zfs
install -D -m644 "${srcdir}"/zfs.bash-completion-r1 "${pkgdir}"/usr/share/bash-completion/completions/zfs
mkdir -p "${pkgdir}"/usr/lib/initcpio/install
}
|
