blob: 7adf94cbcb9fde940aeb3ca98741d11de750c1b2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id$
# Maintainer (Arch): Anatol Pomozov
# Contributor (Arch): Michael Lass <bevan@bi-co.net>
# Contributor (Arch): Philipp Schrader <philipp.schrader+arch@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Parabola changes and rationale:
# - Change architecture to armv7h: uboot-tools is already available in
# Parabola i686 and x86_64 through Arch Linux and Arch Linux 32's
# community repositories
pkgname=uboot-tools
pkgver=2021.04
pkgrel=1
pkgdesc='U-Boot bootloader utility tools'
arch=(armv7h)
url='https://www.denx.de/wiki/U-Boot/WebHome'
license=(GPL)
depends=(openssl)
source=(ftp://ftp.denx.de/pub/u-boot/u-boot-$pkgver.tar.bz2{,.sig})
validpgpkeys=('1A3C7F70E08FAB1707809BBF147C39FF9634B72C')
sha1sums=('a69cf9cf8ddda0935b0bfed86e90fde1124f133d'
'SKIP')
build() {
cd u-boot-$pkgver
make defconfig
make tools-all KBUILD_HOSTLDFLAGS=${LDFLAGS}
}
package() {
install -m 755 -d "$pkgdir"/usr/bin
install -m 755 -t "$pkgdir"/usr/bin/ u-boot-$pkgver/tools/{mk{,env}image,env/fw_printenv,img2srec,dumpimage,netconsole,jtagconsole,ncb}
ln -s fw_printenv "$pkgdir"/usr/bin/fw_setenv
install -m 644 -D u-boot-$pkgver/doc/mkimage.1 "$pkgdir"/usr/share/man/man1/mkimage.1
}
|
