blob: 9d67f54f2dc548ba00e8d604c487ea0879de66e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: freaj <freaj@riseup.net>
# Contributor (AUR): Håvard Pettersson <mail@haavard.me>
# Contributor (AUR): naxuroqa <naxuroqa at gmail.com>
# Contributor (AUR): Boohbah <boohbah at gmail.com>
# Contributor (AUR): Kevin MacMartin <prurigro at gmail dot com>
_pkgname=tox
pkgname=tox-git
pkgver=r3418.4b9425f
pkgrel=1
pkgdesc='Secure, configuration-free, P2P Skype replacement backend'
arch=('i686' 'x86_64')
url='https://tox.im'
license=('GPL3')
depends=(
'libconfig>=1.4'
'libsodium>=1.0'
'libvpx'
'opus'
)
makedepends=('git' 'check')
optdepends=('qtox-git: qt-based Tox client'
'utox-git: lightweight Tox client'
'toxic-git: ncurses-based Tox client')
conflicts=("$_pkgname")
provides=("$_pkgname")
replaces=("$_pkgname")
source=("$_pkgname::git+https://github.com/irungentoo/toxcore.git")
sha512sums=('SKIP')
pkgver() {
cd $_pkgname
printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd $_pkgname
autoreconf -if
./configure \
--prefix=/usr \
--enable-daemon \
--disable-ntox \
--disable-tests
make
}
check() {
cd $_pkgname
make check
}
package() {
cd $_pkgname
make DESTDIR="$pkgdir" install
install -Dm644 ./other/bootstrap_daemon/tox-bootstrapd.service "$pkgdir/usr/lib/systemd/system/tox-bootstrapd.service"
}
|
