blob: a275d67306c672fb117ccb1cf04b46cbbd67cf97 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer (Arch) : M0Rf30
# Contributor (Arch) : Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor (Arch) : Hugo Doria <hugo@archlinux.org>
# Contributor (Arch) : Kessia 'even' Pinheiro <kessiapinheiro at gmail.com>
# Contributor (Arch) : dorphell <dorphell@archlinux.org>
# Contributor (Arch) : Gregor Ibic <gregor.ibic@intelicom.si>
# Maintainer (Parabola) : Aurélien DESBRIÈRES <aurelien@hackers.camp>
pkgname=snort
pkgver=2.9.7.2
pkgrel=1
pkgdesc='A lightweight network intrusion detection system.'
arch=('i686' 'x86_64' 'mips64el')
url='http://www.snort.org'
license=('GPL')
depends=('libdaq' 'libdnet' 'libpcap' 'openssl' 'pcre' 'zlib')
backup=('etc/snort/snort.conf'
'etc/snort/threshold.conf'
'etc/snort/reference.config'
'etc/snort/rules/emerging.conf'
'etc/snort/classification.config')
options=('!makeflags' '!libtool')
install='snort.install'
source=("https://www.snort.org/downloads/snort/${pkgname}-${pkgver}.tar.gz"
"http://rules.emergingthreats.net/open/${pkgname}-2.9.0/emerging.rules.tar.gz"
'snort@.service')
md5sums=('b01e9964827394c39194a0147bc15705'
'SKIP'
'49c7e8dbde680322ff5c4e0883f2b908')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc/snort --with-libpcap-includes=/usr/include/pcap \
--with-daq-includes=/usr/include --with-daq-libraries=/usr/lib/daq/ \
--disable-static-daq
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
mkdir -p "${pkgdir}/etc/snort/rules"
install -d -m755 "${pkgdir}/var/log/snort"
install -D -m644 etc/{*.conf*,*.map} "${pkgdir}/etc/snort/"
# init service file
install -D -m644 ../snort@.service $pkgdir/usr/lib/systemd/system/snort@.service
sed -i 's#/usr/local/lib/#/usr/lib/#' "${pkgdir}/etc/snort/snort.conf"
# emerginthreats rules
echo 'include $RULE_PATH/emerging.conf' >> "${pkgdir}/etc/snort/snort.conf"
cp ${srcdir}/rules/* "${pkgdir}/etc/snort/rules"
}
|
