blob: c123198bad8d65ec273ccc6e691756b13fbcbcc2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: David P. <megver83@parabola.nu>
# Contributor: Alfredo Ramos <alfredo dot ramos at yandex dot com>
# Contributor: Chris <christopher.r.mullins g-mail>
# Contributor: Ainola
# Contributor: speps
pkgname=pythonqt
pkgver=3.2
pkgrel=3
pkgdesc='A dynamic Python binding for Qt applications'
arch=('i686' 'x86_64')
url='http://pythonqt.sourceforge.net/'
license=('LGPL2.1')
depends=('python' 'qt5-multimedia' 'qt5-svg' 'qt5-webkit' 'qt5-declarative')
makedepends=('git' 'qt5-tools')
conflicts=('qt5-python27-git')
replaces=("${pkgname}-qt5")
source=(
"http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/PythonQt-${pkgver}/PythonQt${pkgver}.zip"
'fix_python_version.patch'
'pkgconfig_file.prf'
'create_pkgconfig_file.patch'
)
sha512sums=(
'1ee0f50f5035568b38e945108f5496ba64355c6357c1ea8dfc17ad90fa360540769f94e0b3e0e398176e8a21c8afe139607f0b5a2e82c63f1cbd40201a25e0f0'
'9747898842f60bdfc5c38a54f7516a46b46279c57cbfa6c7f4796aa1ca5771ebb121f07fe4d09d23c60c92530750ee265808484f3e07aaae72065ed51c3896c7'
'a146b46d4fb7162dc4290c662971742a4f85e11b2f5f9d71b4cd52f500ed7f0c3c1cf9034ead2e91f3c4e133446838fa530b3e13d3618617c695f2a433fdbb23'
'9386ec26b3a59de492a9d8c31ca6c4f9e220510070a6d5c0a063618e3f6e7c4db611b27f6b46c028b5613e70453db67c060533e6940d72ff9ea623d80c2f99f9'
)
prepare() {
# Create build directory
mkdir -p "${srcdir}"/build
cd "${srcdir}"/build
cp -R ../PythonQt${pkgver}/* ./
# Fix python version
patch -Np1 < ../fix_python_version.patch
# Add qmake configuration file to generate
# PythonQt pkg-config file (*.pc)
cp ../pkgconfig_file.prf build/
patch -Np1 < ../create_pkgconfig_file.patch
}
build() {
# Building package
cd "${srcdir}"/build
qmake-qt5 \
QMAKE_CFLAGS="${CFLAGS}" \
QMAKE_CXXFLAGS="${CXXFLAGS}" \
CONFIG+=release \
CONFIG+=c++14
make
}
package() {
cd "${srcdir}"/build
# Includes
mkdir -p "${pkgdir}"/usr/include/PythonQt/{gui,extensions/PythonQt_QtAll}
cp ../PythonQt${pkgver}/src/*.h "${pkgdir}"/usr/include/PythonQt/
cp ../PythonQt${pkgver}/src/gui/*.h "${pkgdir}"/usr/include/PythonQt/gui/
cp ../PythonQt${pkgver}/extensions/PythonQt_QtAll/*.h "${pkgdir}"/usr/include/PythonQt/extensions/PythonQt_QtAll/
# Library
mkdir -p "${pkgdir}"/usr/lib
cp -a lib/*.so* "${pkgdir}"/usr/lib/
# pkg-config file
mkdir -p "${pkgdir}"/usr/share/
cp -R pkgconfig "${pkgdir}"/usr/share/
}
|
