blob: 1ff26fd998563b09595ee5c13f99819adcc7cda6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Maintainer: Márcio Silva <coadde@parabola.nu>
# Based on ppsspp package
_pkgbase=ppsspp
pkgbase=ppsspp-git
pkgname=('ppsspp-git' 'ppsspp-qt-git')
pkgver=r19085.01669cb
pkgrel=1
pkgdesc='A PSP emulator written in C++'
arch=('i686' 'x86_64')
url='http://www.ppsspp.org/'
license=('GPL2')
depends=('ffmpeg' 'sdl2')
makedepends=('cmake' 'git' 'glu' 'qt5-tools')
source=("git+https://github.com/hrydgard/ppsspp.git"
'git+https://github.com/hrydgard/ppsspp-lang.git'
'ppsspp-armips::git+https://github.com/Kingcom/armips.git'
'ppsspp.desktop')
sha256sums=('SKIP'
'SKIP'
'SKIP'
'1c332702d0aeced07df7e12ba8530bc3f19a52bc76c355f6c84c141becfd46d8')
pkgver() {
cd ppsspp
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ppsspp
for submodule in lang ext/armips; do
git submodule init ${submodule}
git config submodule.${submodule}.url ../ppsspp-${submodule#*/}
git submodule update ${submodule}
done
for ui in sdl qt; do
if [[ -d build-$ui ]]; then
rm -rf build-$ui
fi
mkdir build-$ui
done
}
build() {
cd ppsspp/build-sdl
cmake .. \
-DCMAKE_BUILD_TYPE='Release' \
-DCMAKE_SKIP_RPATH='TRUE' \
-DUSE_SYSTEM_FFMPEG='TRUE'
make
cd ../build-qt
qmake-qt5 CONFIG+='release' CONFIG+='system_ffmpeg' ../Qt/PPSSPPQt.pro
make
}
package_ppsspp-git() {
provides=("${_pkgbase}")
conflicts=("${_pkgbase}" "${_pkgbase}-qt" "${_pkgbase}-qt-git")
cd ppsspp/build-sdl
install -dm 755 "${pkgdir}"/usr/{bin,share/{applications,pixmaps,ppsspp}}
install -m 755 PPSSPPSDL "${pkgdir}"/usr/bin/ppsspp
cp -dr --no-preserve='ownership' assets "${pkgdir}"/usr/share/ppsspp/
install -m 644 ../assets/unix-icons/icon-512.svg "${pkgdir}"/usr/share/pixmaps/ppsspp.svg
install -m 644 ../../ppsspp.desktop "${pkgdir}"/usr/share/applications/
}
package_ppsspp-qt-git() {
depends+=('qt5-base')
provides=("${_pkgbase}")
conflicts=("${_pkgbase}" "${_pkgbase}-qt" "${_pkgbase}-qt-git")
cd ppsspp/build-qt
install -dm 755 "${pkgdir}"/usr/{bin,share/{applications,pixmaps}}
install -m 755 ppsspp "${pkgdir}"/usr/bin/
install -m 644 ../assets/unix-icons/icon-512.svg "${pkgdir}"/usr/share/pixmaps/ppsspp.svg
install -m 644 ../../ppsspp.desktop "${pkgdir}"/usr/share/applications/
}
# vim: ts=2 sw=2 et:
|
