blob: 23ae2f3740bccc09ae2dba56aae5b60ee71db820 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Luke R. <g4jc@openmailbox.org> GPG: rsa4096/3EAE8697
# Contributor (Arch): Gilrain <gilrain+libre.arch A_T castelmo DOT_ re>
pkgname=pgl
pkgver=2.3.0
pkgrel=2
pkgdesc='A privacy oriented firewall application (GUI).'
arch=('i686' 'x86_64')
url='http://sourceforge.net/projects/peerguardian/'
license=('GPL3')
depends=('bash' 'systemd' 'dbus' 'coreutils' 'procps-ng' 'logrotate' 'wget' 'iptables' 'libnetfilter_queue' 'qt4' 'polkit-qt4' 'whois' 'gksudo')
optdepends=('unzip: for zipped blocklists'
'p7zip: for 7z blocklists'
'net-tools: to whitelist local IP addresses'
'networkmanager: to whitelist newly started network interfaces'
'smtp-forwarder: to send reports'
'tcptraceroute: to diagnose connection problems')
makedepends=('zlib')
conflicts=('pgl-cli' 'pgl-git')
backup=('etc/pgl/allow.p2p'
'etc/pgl/blocklists.list'
'etc/pgl/pglcmd.conf'
'etc/logrotate.d/pglcmd'
'etc/logrotate.d/pgld')
install=install
changelog=changelog
source=("https://downloads.sourceforge.net/project/peerguardian/PeerGuardian%20Linux/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('535f13d6b17bbea099e415e9dd463ebf4e2ffa9af4d8ae96c7ace2667c84380f506018aca2b6b6a6d4ca1e2afd24fc6eaf9544eb00710645d562f2aa1fa5a1a7')
build() {
cd "$pkgname-$pkgver"
# makes sure qt4 is used
export QMAKE=qmake-qt4
export MOC=moc-qt4
export UIC=uic-qt4
export RCC=rcc-qt4
./configure --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc --localstatedir=/var --datarootdir=/usr/share \
--with-piddir=/run --with-systemd --disable-cron --without-initddir
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
# integrates daemon log in systemd journal
sed -i '/^LOG_SYSLOG/s/0/1/g' $pkgdir/usr/lib/pgl/pglcmd.defaults
}
|
