blob: 9c5327403f1299ca8dfc09c3687b695acae6be49 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer (AUR): Philipp Wolfer <ph.wolfer@gmail.com>
# parabola changes and rationale:
# no changes.
pkgname=peek
pkgver=1.2.1
pkgrel=1
pkgdesc="Simple screen recorder with an easy to use interface"
arch=('i686' 'x86_64' 'armv7h')
url="https://github.com/phw/peek"
license=('GPL3')
depends=(gtk3 libkeybinder3 ffmpeg)
makedepends=(cmake vala gettext txt2man)
optdepends=(
'gst-plugins-good: WebM output under Gnome Shell'
'gst-plugins-ugly: MP4 output under Gnome Shell'
'gifski: High quality GIF animations with thousands of colors'
)
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/phw/${pkgname}/archive/${pkgver}.tar.gz)
sha256sums=('7035ad6817306bf93b0052bf989120793e26b3fbcba51dda3cdf345342214af5')
prepare() {
mkdir -p build
}
build() {
cd "build"
cmake "${srcdir}/${pkgname}-${pkgver}" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_TESTS=ON \
-DCMAKE_BUILD_TYPE=Release \
-DGSETTINGS_COMPILE=OFF \
-DENABLE_FILECHOOSERNATIVE=ON
make
}
check() {
cd "build"
make test
}
package() {
cd "build"
make DESTDIR=${pkgdir} install
}
|
