blob: c167011fb3e2c847e1671acaab336c404a21189e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer (Arch): Antonio Rojas <nqn1976 @ gmail.com>
# Contributor (Arch): Alexander Rødseth <rodseth@gmail.com>
# Contributor (Arch): Angel Velasquez <angvp@archlinux.org>
# Contributor (Arch): Hugo Doria <hugo@archlinux.org>
# Contributor (Arch): Andrew Wright <andreww@photism.org>
# Maintainer: Guest One <theguestone at gmail dot com>
pkgname=nicotine
pkgver=1.2.16
pkgrel=7
pkgdesc='Soulseek music-sharing client, written in python'
arch=('x86_64' 'i686')
url='http://sourceforge.net/projects/nicotine-plus/'
license=('GPL')
depends=('pygtk' 'mutagen')
makedepends=('setconf')
optdepends=('python2-geoip: to enable Geographical blocker' 'python2-sexy: spell checking support' 'miniupnpc-python2: UPNP support')
source=("http://downloads.sourceforge.net/project/nicotine-plus/nicotine-plus/${pkgver}/${pkgname}+-${pkgver}.tar.bz2")
sha256sums=('71e5b33e273daaf072dbf63839536c14d7ead9d149323d50eee09f7429e34c1d')
prepare() {
cd "$srcdir/${pkgname}+-$pkgver"
# Fix for FS#22476
setconf files/nicotine.desktop Icon nicotine-plus-32px
# Python fix
sed -i -e 's|/usr/bin/env python|/usr/bin/env python2|' \
-e 's|/usr/bin/python|/usr/bin/python2|' pynicotine/{,gtkgui/}*.py
}
build() {
cd "$srcdir/${pkgname}+-$pkgver/trayicon"
python2 autogen.py
make
}
package() {
cd "$srcdir/${pkgname}+-$pkgver"
python2 setup.py install --root="$pkgdir"
cd trayicon
make DESTDIR="$pkgdir" install
ln -s nicotine.py "$pkgdir/usr/bin/nicotine"
}
# vim:set ts=2 sw=2 et:
|
