blob: f87ce7e2a8992ca4adc5020ecfb141bed058a666 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: SJ_UnderWater
# Based on netatalk package :
# Maintainer: Dominik Dingel <mail at wodar dot de>
# Contributor: William Udovich <nerdzrule7 at earthlink dot net>
# Contributor: Farhan Yousaf <farhany at xaviya dot com>
pkgname=netatalk
pkgver=3.0.3
pkgrel=2
pkgdesc='A kernel-level implementation of AFP services'
arch=('i686' 'x86_64' 'mips64el')
url='http://netatalk.sourceforge.net'
license=('GPL')
depends=('avahi>=0.6' 'libldap' 'libgcrypt>=1.2.3' 'libevent' 'python' 'dbus-glib')
replaces=('netatalk-git' 'netatalk2')
backup=('etc/afp.conf'
'etc/extmap.conf')
options=('!libtool')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://iweb.dl.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$pkgname-$pkgver.tar.bz2)
md5sums=('0a6f3acefd27ad63d2cde6ae4702e1b4')
build() {
cd $pkgname-$pkgver
sed -i -e 's:"/lib/systemd:"/usr/lib/systemd:' -e 's/x"linux/x"generic/' macros/netatalk.m4
sed -i 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' {configure.ac,libevent/configure.in}
cp /usr/share/automake*/missing .
autoreconf -i
./configure --prefix=/usr \
--localstatedir=/var/state \
--sysconfdir=/etc \
--with-init-style=systemd \
--with-cracklib \
--with-cnid-cdb-backend \
--enable-pgp-uam \
--with-libevent=no
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
