blob: 9221aae5da4e4257d8bd68e3d4165a253d82613e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer : Aurelien Desbrieres <aurelien@hackers.camp>
# Contributor: Levente Polyak <levente[at]leventepolyak[dot]net>
# Contributor: Sébastien Luttringer <seblu@aur.archlinux.org>
pkgname=lynis
_pkgname=Lynis
pkgver=1.6.4
pkgrel=1
pkgdesc='Security and system auditing tool to harden Unix/Linux systems'
url='http://cisofy.com/lynis/'
license=('GPL3')
arch=('any')
backup=('etc/lynis/default.prf')
depends=('sh')
optdepends=('net-tools: networking tests'
'bash-completion: completion for bash')
install=lynis.install
source=(https://github.com/CISOfy/${_pkgname}/archive/${pkgver}.tar.gz)
prepare() {
cd ${_pkgname}-${pkgver}
sed -e 's|/path/to/lynis|/usr/bin/lynis|g' -i extras/systemd/lynis.service
}
package() {
cd ${_pkgname}-${pkgver}
# profile
install -Dm 644 default.prf "${pkgdir}/etc/${pkgname}/default.prf"
# binary
install -Dm 755 "${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
# plugins, include, db
install -d "${pkgdir}/usr/share/${pkgname}"
cp -a db include plugins "${pkgdir}/usr/share/${pkgname}"
# doc files
install -d "${pkgdir}/usr/share/doc/${pkgname}"
install -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" README INSTALL CHANGELOG FAQ
# manpage
install -Dm 644 "${pkgname}.8" "${pkgdir}/usr/share/man/man8/${pkgname}.8"
# completion
install -Dm 644 extras/bash_completion.d/${pkgname} "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
# systemd
install -d "${pkgdir}/usr/lib/systemd/system/"
install -m 644 extras/systemd/{lynis.service,lynis.timer} "${pkgdir}/usr/lib/systemd/system/"
}
# vim:set ts=2 sw=2 ft=sh et:
|
