blob: de1c919a4d3feaec33f429f85936dfb51f3f749f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: bill-auger <bill-auger@programmer.net>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=libgksu
pkgver=2.0.12
pkgrel=8.parabola2
pkgdesc="gksu authorization library"
arch=(x86_64 i686)
url="http://www.nongnu.org/gksu/index.html"
license=(GPL)
depends=('gconf' 'gtk2' 'libgnome-keyring' 'libgtop' 'startup-notification')
makedepends=('intltool' 'gtk-doc')
options=('!emptydirs')
source=(http://people.debian.org/~kov/gksu/${pkgname}-${pkgver}.tar.gz
libgksu-2.0.0-fbsd.patch
libgksu-2.0.12-automake-1.11.2.patch
libgksu-2.0.12-fix-make-3.82.patch
libgksu-2.0.12-notests.patch
libgksu-2.0.12-revert-forkpty.patch
libgksu-2.0.7-libs.patch
libgksu-2.0.7-polinguas.patch)
sha256sums=('22f9cfc3627dcb6774b9aff66c6ea6554f3b34b82bbfa2467b821e67874c3faf'
'bf0343df8e316ac227da7c40a889dd5128da081a640c187dfb743b4f213c3792'
'8d6573025758e5f5c569963fab2d99f406ea50fb055bf06693868ba976c5dd66'
'4634482b8b9187fd6eaa8560fc88a3f0f93f3a7a143b5b42cdc9ffa2ac112d11'
'6cac450d0e3d8950c25fec078cc41478138fd14afe3492e96f7b889178725707'
'e75597115bdc7c30ee223d73f5c071d7cceffd04fbf2798d1aa17920fae865dd'
'62d1d576bd8e4b07494a788d6760463ee2090e341dae5113d5f763a3549f6b6a'
'f360bbd003492e7bc7818f97988ff3af81a14c4278b1f788b0b919f743d7ee8f')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np1 -i "${srcdir}/libgksu-2.0.0-fbsd.patch"
patch -Np1 -i "${srcdir}/libgksu-2.0.7-libs.patch"
patch -Np1 -i "${srcdir}/libgksu-2.0.7-polinguas.patch"
patch -Np1 -i "${srcdir}/libgksu-2.0.12-revert-forkpty.patch"
patch -Np0 -i "${srcdir}/libgksu-2.0.12-fix-make-3.82.patch"
patch -Np1 -i "${srcdir}/libgksu-2.0.12-notests.patch"
patch -Np1 -i "${srcdir}/libgksu-2.0.12-automake-1.11.2.patch"
touch NEWS README
intltoolize --force --copy --automake
autoreconf -fi
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static --disable-schemas-install --disable-gtk-doc
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install
rm -f ${pkgdir}/usr/lib/*.a
install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain libgksu ${pkgdir}/etc/gconf/schemas/*.schemas
rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
}
|
