blob: 86cef7e4c40a30de65ecc99c4888c62223042d44 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: David P. <megver83@parabola.nu>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
_pkgbase=kate
pkgbase=kate-root
pkgname=('kwrite-root'
'kate-root')
pkgver=17.04.1
pkgrel=1
arch=('armv7h' 'i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
makedepends=('extra-cmake-modules' 'kdoctools' 'python' 'plasma-framework' 'knewstuff' 'ktexteditor'
'threadweaver' 'kitemmodels' 'kactivities')
source=("https://download.kde.org/stable/applications/${pkgver}/src/${_pkgbase}-${pkgver}.tar.xz"{,.sig}
"https://gitlab.com/Megver83/kdebase-root-patches/raw/master/0001-Defuse-root-block.patch"{,.sig})
sha256sums=('34eee6c384e2c2776c7d0ab65e7217e730cdbdecb82578c9dc90380cb82affd2'
'SKIP'
'97926a28409205bff73df7788afcbce5229a60734db26704ffb10535c74bb96c'
'SKIP')
validpgpkeys=('CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7' # Albert Astals Cid <aacid@kde.org>
'6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78' # David P.
)
options=(!emptydirs)
prepare() {
mkdir -p build
cd $srcdir/${_pkgbase}-${pkgver}
patch -p1 -i $srcdir/0001-Defuse-root-block.patch
}
build() {
cd build
cmake ../${_pkgbase}-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DSYSCONF_INSTALL_DIR=/etc \
-DBUILD_TESTING=OFF
make
}
package_kwrite-root() {
pkgdesc="Text Editor, patched to be able to run as root"
groups=('kde-applications' 'kdebase')
url="https://www.kde.org/applications/utilities/kwrite/"
depends=('ktexteditor' 'kactivities' 'hicolor-icon-theme')
replaces=('kdebase-kwrite' 'kwrite')
conflicts=('kdebase-kwrite' 'kwrite')
provides=('kdebase-kwrite' 'kwrite')
cd build
make DESTDIR="${pkgdir}" install
find "$pkgdir" -type f -name '*kate*' -exec rm {} \;
rm -r "$pkgdir"/usr/lib/qt/plugins/ktexteditor \
"$pkgdir"/usr/share/doc/HTML/*/{kate,katepart} \
"$pkgdir"/usr/share/katexmltools \
"$pkgdir"/usr/share/locale/*/LC_MESSAGES/{kterustcompletion,tabswitcherplugin}.mo \
"$pkgdir"/usr/share/plasma/plasmoids
}
package_kate-root() {
pkgdesc="Advanced Text Editor, patched to be able to run as root"
groups=('kde-applications' 'kdebase')
url="https://www.kde.org/applications/utilities/kate/"
depends=('knewstuff' 'ktexteditor' 'threadweaver' 'kitemmodels' 'kactivities' 'hicolor-icon-theme')
replaces=('kdesdk-kate' 'kate')
conflicts=('kdesdk-kate' 'kate')
provides=('kdesdk-kate' 'kate')
optdepends=('konsole: open a terminal in Kate')
cd build
make DESTDIR="${pkgdir}" install
find "$pkgdir" -type f -name '*kwrite*' -exec rm {} \;
rm -r "$pkgdir"/usr/share/doc/HTML/*/kwrite
}
|
