blob: ef0bdf4b9551a791308976585ee1a2a87a7a3c6a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
_pkgbase=imagemagick
pkgname=imagemagick-nox
pkgver=6.9.9.23
pkgrel=1
arch=(i686 x86_64 armv7h)
pkgdesc="An image viewing/manipulation program (without X11 support)"
url="http://www.imagemagick.org/"
license=(custom)
# Remove libxt, libxext, opencl-headers, opencl-id-loader, libcl, glu
makedepends=(libltdl lcms2 fontconfig ghostscript
openexr libwmf librsvg libxml2 liblqr openjpeg2 libraw libraqm
libwebp subversion)
# Remove libxt, libxext, libcl, opencl-icd-loader
depends=(libltdl lcms2 fontconfig liblqr libraqm)
optdepends=('imagemagick-doc: for additional information'
'ghostscript: for Ghostscript support'
'openexr: for OpenEXR support'
'openjpeg2: for JP2 support'
'libwmf: for WMF support'
'librsvg: for SVG support'
'libxml2: for XML support'
'libpng: for PNG support'
'libwebp: for WEBP support'
'libraw: for DNG support')
backup=("etc/ImageMagick-${pkgver%%.*}/coder.xml"
"etc/ImageMagick-${pkgver%%.*}/colors.xml"
"etc/ImageMagick-${pkgver%%.*}/delegates.xml"
"etc/ImageMagick-${pkgver%%.*}/log.xml"
"etc/ImageMagick-${pkgver%%.*}/magic.xml"
"etc/ImageMagick-${pkgver%%.*}/mime.xml"
"etc/ImageMagick-${pkgver%%.*}/policy.xml"
"etc/ImageMagick-${pkgver%%.*}/quantization-table.xml"
"etc/ImageMagick-${pkgver%%.*}/thresholds.xml"
"etc/ImageMagick-${pkgver%%.*}/type.xml"
"etc/ImageMagick-${pkgver%%.*}/type-dejavu.xml"
"etc/ImageMagick-${pkgver%%.*}/type-ghostscript.xml"
"etc/ImageMagick-${pkgver%%.*}/type-windows.xml")
options=('!docs' 'libtool' '!emptydirs')
provides=("$_pkgbase=$pkgver")
conflicts=("$_pkgbase")
replaces=("imagemagick-srv")
source=(http://www.imagemagick.org/download/ImageMagick-${pkgver%.*}-${pkgver##*.}.tar.xz{,.asc}
perlmagick.rpath.patch)
sha256sums=('88a422ecc2888745373586b04f1ebd8e91ca090bbf133c2270f66fc716fba631'
'SKIP'
'17218bbecc17f3c7a86935a09d5a47e46113a1fc28f7d91c2fe495019cc36088')
validpgpkeys=('D8272EF51DA223E4D05B466989AB63D48277377A')
prepare() {
cd ImageMagick-${pkgver%.*}-${pkgver##*.}
sed '/AC_PATH_XTRA/d' -i configure.ac
patch -p0 -i "$srcdir/perlmagick.rpath.patch"
autoreconf --force --install
}
build() {
cd ImageMagick-${pkgver%.*}-${pkgver##*.}
[[ $CARCH = "i686" ]] && EXTRAOPTS="--with-gcc-arch=i686"
[[ $CARCH = "x86_64" ]] && EXTRAOPTS="--with-gcc-arch=x86-64"
[[ $CARCH = "armv7h" ]] && EXTRAOPTS="--with-gcc-arch=armv7h"
no_x=yes with_x=no \
./configure --prefix=/usr --sysconfdir=/etc --with-modules \
--enable-hdri --with-wmf --with-openexr --with-xml \
--with-webp --with-gslib --with-gs-font-dir=/usr/share/fonts/Type1 \
--with-perl --with-perl-options="INSTALLDIRS=vendor" --with-lqr --with-rsvg \
--disable-opencl --with-openjp2 --without-gvc --without-djvu --without-autotrace \
--without-jbig --without-fpx --without-dps --without-fftw $EXTRAOPTS
make
}
check() {
cd ImageMagick-${pkgver%.*}-${pkgver##*.}
# make check
}
package() {
cd ImageMagick-${pkgver%.*}-${pkgver##*.}
make -j1 DESTDIR="${pkgdir}" install
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 NOTICE "${pkgdir}/usr/share/licenses/${pkgname}/NOTICE"
# Cleaning
rm -f "$pkgdir"/usr/lib/*.la
# remove useless display
rm -vf "$pkgdir/usr/bin/display"
# template start; name=perl-binary-module-dependency; version=1;
if [[ $(find "$pkgdir/usr/lib/perl5/" -name "*.so") ]]; then
_perlver_min=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]);')
_perlver_max=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]+1);')
depends+=("perl>=$_perlver_min" "perl<$_perlver_max")
fi
# template end;
}
|
