blob: 491441c6bd658951c0fc98824d0bafa3a77e66ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer (AUR): skydrome <skydrome@i2pmail.org>
# Contributor (AUR): skydrome <skydrome@i2pmail.org>
# Maintainer: Freemor <freemor@freemor.ca>
########[ OPTIONS ]########################################
#
# Uncomment if you do not want to build all language translations
#export LG2=en
#
###########################################################
# parabola changes and rationalle:
# no changes.
pkgname=i2p
pkgver=0.9.38
pkgrel=1
pkgdesc="A distributed anonymous network"
url="https://geti2p.net"
license=('GPL2')
arch=('any')
depends=('java-runtime>=7' 'java-service-wrapper')
makedepends=('apache-ant' 'java-environment>=7')
[[ "$LG2" != 'en' ]] && makedepends+=('gettext')
#optdepends=('gtk2: for rrd graphs')
conflicts=('i2p-bin' 'i2p-dev')
backup=('opt/i2p/wrapper.config')
install='i2p.install'
#_url="https://download.i2p2.de/releases/${pkgver}"
_url="https://launchpad.net/i2p/trunk/${pkgver}/+download"
source=("${_url}/i2psource_${pkgver}.tar.bz2"{,.sig}
'i2prouter.service' 'i2prouter.sh' 'wrapper.config' 'router.config')
sha256sums=('65fe327fdd11272a764c9e1c6ae1f38b151cea9003216b861c7ff2b281ca2970'
'SKIP'
'9bb899ece87099716da29bac8b7da02916fc325699b68989e73c1fe333a6342f'
'ea8f97e66461d591b1819eab39bbc40056b89ae12f7729b3dd9fd2ce088e5e53'
'315d8128969b372bb553dc2170c3e0709f52e01be77c1db1f071d83569126a70'
'7a4688db826c3dddb762976cd8c9a5d465255c3577069243d8e5af941a4126e2')
# https://geti2p.net/en/get-involved/develop/release-signing-key
validpgpkeys=('2D3D2D03910C6504C1210C65EE60C0C8EE7256A8')
build() {
cd "$srcdir/$pkgname-$pkgver"
export ANT_HOME=/usr/share/ant
export ANT_OPTS="-Dfile.encoding=UTF-8"
ant preppkg-linux-only
}
package() {
cd "$srcdir/$pkgname-$pkgver"
install -dm755 "$pkgdir/usr/lib/tmpfiles.d"
install -dm755 "$pkgdir/usr/bin"
install -dm750 "$pkgdir/opt/i2p"
cp -r pkg-temp/* "$pkgdir/opt/i2p"
cp "$srcdir/wrapper.config" "$pkgdir/opt/i2p"
install -Dm644 "$srcdir/router.config" "$pkgdir/opt/i2p/router.config"
install -Dm755 "$srcdir/i2prouter.sh" "$pkgdir/opt/i2p/i2prouter"
install -Dm644 "$srcdir/i2prouter.service" "$pkgdir/usr/lib/systemd/system/i2prouter.service"
install -Dm644 "$pkgdir/opt/i2p/man/eepget.1" "$pkgdir/usr/share/man/man1/eepget.1"
install -Dm644 "$pkgdir/opt/i2p/LICENSE.txt" "$pkgdir/usr/share/licenses/i2p/LICENSE"
mv "$pkgdir"/opt/i2p/licenses/* "$pkgdir/usr/share/licenses/i2p/"
ln -s /opt/i2p/{eepget,i2prouter} "$pkgdir/usr/bin/"
chmod +x "$pkgdir"/opt/i2p/{eepget,i2prouter}
echo 'd /run/i2p 0700 i2p i2p -' >"$pkgdir/usr/lib/tmpfiles.d/i2prouter.conf"
sed -i "$pkgdir"/opt/i2p/eepget \
-e 's:%INSTALL_PATH:/opt/i2p:g'
sed -i "$pkgdir"/opt/i2p/clients.config \
-e "s:clientApp.4.startOnLoad=.*:clientApp.4.startOnLoad=false:"
rm -r "$pkgdir"/opt/i2p/{osid,postinstall.sh,runplain.sh,INSTALL-headless.txt,LICENSE.txt,licenses,man,lib/wrapper*}
}
|
