blob: eb514675a7e408f8f66a8e77dbce12ef74f7f6b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer (AUR): Wayne Hartmann (DH4) <wayne@bitstorm.pw>
# Contributor (AUR): György Balló <ballogy@freestart.hu>
# Contributor (AUR): Hyperair <hyperair@gmail.com>
# Contributor (AUR): kumico <norrian@gmail.com>
# Contributor (AUR): adamruss <mail@russ.co.il>
# Maintainer : Parabola GNU / Linux-libre Aurelien Desbrieres <aurelien@cwb.io>
# parabola changes and rationale:
# no changes.
pkgname=gnome-rdp
pkgver=0.3.1.0
pkgrel=3
pkgdesc="Remote desktop client for the GNOME Desktop with RDP/VNC/SSH capabilities, written in C Sharp"
arch=('any')
url="http://sourceforge.net/projects/gnome-rdp/"
license=('GPL' 'LGPL')
depends=('gtk-sharp-2' 'gnome-keyring-sharp' 'mono')
optdepends=('openssh: SSH client'
'gnome-terminal: required for the SSH client'
'rdesktop: RDP client'
'tightvnc: VNC client')
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz
appindicator.patch)
md5sums=('3c1329702914f8b1c213c0bb00d078cf'
'480c69cab53fa79a015d0f2b7e1df9c4')
build() {
cd "$srcdir/$pkgname-$pkgver"
sed -i 's/tight-vncviewer/vncviewer/' Sessions/SessionCollection.cs
patch -R -Np3 -i "$srcdir/appindicator.patch"
sed -i 's/pkglib_SCRIPTS/programfiles_SCRIPTS/' Makefile.include
sed -i 's|@expanded_libdir@|@prefix@/@libdir@|' gnome-rdp.in
autoreconf -fi
sed -i 's|GMCS|DMCS|g' configure
sed -i 's|gmcs|dmcs|g' configure
sed -i 's|GMCS|DMCS|g' Makefile.in
sed -i 's|gmcs|dmcs|g' Makefile.in
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
# Install desktop and icon files
install -Dm644 Menu/$pkgname.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
install -Dm644 Menu/$pkgname.png "$pkgdir/usr/share/pixmaps/$pkgname.png"
# Runtime work-around
sed -i "s|exec mono.*|exec mono \-\-runtime\=v4\.0 \"\/usr\/\$\{exec\_prefix\}\/lib\/gnome\-rdp\/gnome\-rdp\.exe\" \"\$\@\"|g" "$pkgdir/usr/bin/gnome-rdp"
}
|
