blob: 313f2422b462f34d60ee23b8e2fc66f58b8a4e47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Márcio Silva <coadde@parabola.nu>
# Maintainer (Arch): Daniel Isenmann <daniel@archlinux.org>
_pkgname=gimp
pkgname=gimp-git
pkgver=r35782.feaacaf
pkgrel=1
pkgdesc="GNU Image Manipulation Program"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.${_pkgname}.org/"
license=('GPL' 'LGPL')
depends=('pygtk' 'lcms2' 'libxpm' 'libwmf' 'libxmu' 'librsvg' 'libmng' 'dbus-glib'
'libgexiv2' 'gegl-git' 'jasper' 'desktop-file-utils' 'hicolor-icon-theme' 'babl'
'openexr' 'libgudev' 'libmypaint')
makedepends=('intltool' 'webkitgtk2' 'poppler-glib' 'alsa-lib' 'iso-codes' 'ghostscript'
'git' 'gtk-doc')
optdepends=('gutenprint: for sophisticated printing only as gimp has built-in cups print support'
'webkitgtk2: for the help browser'
'poppler-glib: for pdf support'
'alsa-lib: for MIDI event controller module'
'ghostscript: for postscript support')
options=('!makeflags')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
install=${_pkgname}.install
source=(${_pkgname}-${pkgver}::git+git://git.gnome.org/${_pkgname}.git
linux-kernel.gpl)
md5sums=('SKIP'
'36854ad996c96df06249f1e94bd996d5')
pkgver() {
cd "${srcdir}/${_pkgname}-${pkgver}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare () {
cd "${srcdir}/${_pkgname}-${pkgver}"
# fix headers patch
sed -i 's|[<]mypaint-brush[.]h[>]|"libmypaint-git/mypaint-brush.h"|
s|[<]mypaint-tiled-surface[.]h[>]|"libmypaint-git/mypaint-tiled-surface.h"|
' app/paint/gimpmybrush.c
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
./autogen.sh
PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
--enable-mp --enable-gimp-console --enable-python --without-aa
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' "${pkgdir}"/usr/lib/gimp/2.0/plug-ins/*.py
install -D -m644 "${srcdir}/linux-kernel.gpl" "${pkgdir}/usr/share/gimp/2.0/palettes/Linux-kernel.gpl"
ln -s gimp-2.9 "${pkgdir}/usr/bin/gimp"
ln -s gimp-console-2.9 "${pkgdir}/usr/bin/gimp-console"
ln -s gimptool-2.0 "${pkgdir}/usr/bin/gimptool"
ln -sf gimp-2.9.1.gz "${pkgdir}/usr/share/man/man1/gimp.1.gz"
ln -sf gimp-console-2.9.1.gz "${pkgdir}/usr/share/man/man1/gimp-console.1.gz"
ln -sf gimptool-2.0.1.gz "${pkgdir}/usr/share/man/man1/gimptool.1.gz"
ln -sf gimprc-2.9.5.gz "${pkgdir}/usr/share/man/man5/gimprc.5.gz"
}
|
