blob: c53a8b9cfb4e601f8308b0e8bf5a06daece3c1c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Contributor (AUR): David Virgilio <drvirgilio@gmail.com>
# Contributor (AUR): David Zaragoza <david@zaragoza.com.ve>
# Contributor (AUR): Clément Démoulins <clement@archivel.fr>
# Maintainer (AUR): Raphaël Doursenaud <rdoursenaud@free.fr>
pkgname=frescobaldi
pkgver=3.1.2
pkgrel=2
pkgdesc="A LilyPond sheet music text editor."
arch=('any')
url="http://www.frescobaldi.org/"
license=('GPL')
depends=(
'hyphen'
'poppler'
'python>=3.3'
'python-ly>=0.9.5'
'python-poppler-qt5'
'python-pyqt5>=5.9'
'python-sip'
'qt5-base>=5.9'
'qt5-svg>=5.9'
'qt5-webkit>=5.9'
'hicolor-icon-theme'
'tango-icon-theme'
)
optdepends=(
'lilypond: Music engraving (recommended)'
# python-portmidi is currently a python2 package
# 'python-portmidi: MIDI playback (default engine)'
'python-pygame: MIDI playback (alternate engine)'
'portmidi: MIDI playback (fallback engine)'
'hyphen-de: German hyphenation rules'
'hyphen-en: English hyphenation rules'
'hyphen-es: Spanish hyphenation rules'
'hyphen-fr: French hyphenation rules'
'hyphen-hu: Hungarian hyphenation rules'
'hyphen-it: Italian hyphenation rules'
'hyphen-nl: Dutch hyphenation rules'
'hyphen-ro: Romanian hyphenation rules'
'python-pycups: Printing to a local CUPS server'
)
source=(https://github.com/frescobaldi/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha256sums=('5c2cffb8282cd9faef1585808bd800d1eb3c0db4cc464a61ce8576dbf7ef9b20')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Provided by tango-icon-theme
rm -rf "frescobaldi_app/icons/Tango"
# Provided by hyphen-*
rm -f frescobaldi_app/hyphdicts/hyph_*.dic
rm -f frescobaldi_app/hyphdicts/README*
# error in setup.cfg: command 'install' has no such option 'single_version_externally_managed'
sed -i 's|single-version-externally-managed.*||' setup.cfg
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}/" --optimize=1
}
|
