blob: 7e1b1d3626d327ac86002b3a30297a02c8805804 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (Arch): Juergen Hoetzel <juergen@archlinux.org>
# Contributor (Arch): Renchi Raju <renchi@green.tam.uiuc.edu>
_pkgname=emacs
pkgname=emacs-lucid
pkgver=24.4
pkgrel=1.1
pkgdesc="The extensible, customizable, self-documenting real-time display editor"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnu.org/software/emacs/emacs.html"
license=('GPL3')
depends=('librsvg' 'gpm' 'giflib' 'libxpm' 'libotf' 'm17n-lib' 'hicolor-icon-theme' 'gconf' 'desktop-file-utils' 'alsa-lib' 'imagemagick' 'gnutls')
install=emacs.install
source=(ftp://ftp.gnu.org/gnu/emacs/$_pkgname-$pkgver.tar.xz{,.sig})
md5sums=('ad487658ad7421ad8d7b5152192eb945'
'SKIP')
pkgdesc+=", with the Lucid X11 toolkit"
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
build() {
cd "$srcdir"/$_pkgname-$pkgver
ac_cv_lib_gif_EGifPutExtensionLast=yes ./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib \
--localstatedir=/var --with-x-toolkit=lucid --with-xft
make
}
package() {
cd "$srcdir"/$_pkgname-$pkgver
make DESTDIR="$pkgdir" install
# remove conflict with ctags package
mv "$pkgdir"/usr/bin/{ctags,ctags.emacs}
mv "$pkgdir"/usr/share/man/man1/{ctags.1.gz,ctags.emacs.1}
# remove conflict with texinfo
rm "$pkgdir"/usr/share/info/info.info.gz
# fix user/root permissions on usr/share files
find "$pkgdir"/usr/share/emacs/$pkgver -exec chown root:root {} \;
# fix perms on /var/games
chmod 775 "$pkgdir"/var/games
chmod 775 "$pkgdir"/var/games/emacs
chmod 664 "$pkgdir"/var/games/emacs/*
chown -R root:games "$pkgdir"/var/games
}
|
