1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Maintainer (Arch): Charles Bos <charlesbos1 AT gmail>
# Contributor (Arch): Rob McCathie <archaur at rmcc dot com dot au
# Contributor (Arch): /dev/rs0 <rs0@secretco.de.com>
# Contributor (Arch): Iven Hsu <ivenvd AT gmail>
# Contributor (Arch): Nathan Hulse <nat.hulse@gmail.com>
pkgname=compiz
pkgver=0.9.13.0
pkgrel=2
pkgdesc="Composite manager for Aiglx and Xgl, with plugins and CCSM"
arch=('i686' 'x86_64')
url="https://launchpad.net/compiz"
license=('GPL' 'LGPL' 'MIT')
depends=('boost' 'xorg-server' 'libxcomposite' 'startup-notification' 'librsvg' 'dbus' 'mesa' 'libxslt' 'fuse' 'glibmm' 'libxrender' 'libwnck3' 'pygtk' 'desktop-file-utils' 'pyrex' 'protobuf' 'metacity' 'glu' 'libsm' 'dconf')
makedepends=('cmake' 'intltool')
optdepends=(
'xorg-xprop: grab various window properties for use in window matching rules'
)
conflicts=('compiz-core')
source=("https://launchpad.net/${pkgname}/${pkgver:0:6}/${pkgver}/+download/${pkgname}-${pkgver}.tar.bz2"
"focus-prevention-disable.patch"
"gtk-extents.patch"
"trailfocus-fix.patch")
sha256sums=('f08eb54d578be559e3e723f3fe4291a56f5c96b2fdfb9c9e74ebb6596a1ca702'
'f4897590b0f677ba34767a29822f8f922a750daf66e8adf47be89f7c2550cf4b'
'16ddb6311ce42d958505e21ca28faae5deeddce02cb558d55e648380274ba4d9'
'01e94ac52cd39eb5462a8505c7df61c7b14b05159de64f8700dfadb524bdb2ce')
prepare() {
cd "${pkgname}-${pkgver}"
# Fix decorator start command
sed -i 's/exec \\"${COMPIZ_BIN_PATH}compiz-decorator\\"/exec \/usr\/bin\/compiz-decorator/g' plugins/decor/decor.xml.in
# Set focus prevention level to off which means that new windows will always get focus
patch -Np1 -i "${srcdir}/focus-prevention-disable.patch"
# Use Python 2
find -type f \( -name 'CMakeLists.txt' -or -name '*.cmake' \) -exec sed -e 's/COMMAND python/COMMAND python2/g' -i {} \;
find compizconfig/ccsm -type f -exec sed -e 's|^#!.*python|#!/usr/bin/env python2|g' -i {} \;
# Fix incorrect extents for GTK+ tooltips, csd etc
patch -Np1 -i "${srcdir}/gtk-extents.patch"
# Fix ambiguous function call in trailfocus plugin
patch -Np1 -i "${srcdir}/trailfocus-fix.patch"
}
build() {
cd "${pkgname}-${pkgver}"
export PYTHON="/usr/bin/python2"
mkdir build; cd build
cmake .. \
-DCMAKE_BUILD_TYPE="Release" \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="/usr/lib" \
-DCOMPIZ_DISABLE_SCHEMAS_INSTALL=On \
-DCOMPIZ_BUILD_WITH_RPATH=Off \
-DCOMPIZ_PACKAGING_ENABLED=On \
-DBUILD_GTK=On \
-DBUILD_METACITY=On \
-DBUILD_KDE4=Off \
-DCOMPIZ_BUILD_TESTING=Off \
-DCOMPIZ_WERROR=Off \
-DCOMPIZ_DEFAULT_PLUGINS="composite,opengl,decor,resize,place,move,compiztoolbox,staticswitcher,regex,animation,wall,ccp" \
make
}
package() {
cd "${pkgname}-${pkgver}/build"
make DESTDIR="${pkgdir}" install
# findcompiz_install needs COMPIZ_DESTDIR and install needs DESTDIR
# make findcompiz_install
CMAKE_DIR=$(cmake --system-information | grep '^CMAKE_ROOT' | awk -F\" '{print $2}')
install -dm755 "${pkgdir}${CMAKE_DIR}/Modules/"
install -m644 ../cmake/FindCompiz.cmake "${pkgdir}${CMAKE_DIR}/Modules/"
# Add documentation
install -dm755 "${pkgdir}/usr/share/doc/compiz/"
install ../{AUTHORS,NEWS,README} "${pkgdir}/usr/share/doc/compiz/"
# Add the gsettings schema files
if ls generated/glib-2.0/schemas/ | grep -qm1 .gschema.xml; then
install -dm755 "${pkgdir}/usr/share/glib-2.0/schemas/"
install -m644 generated/glib-2.0/schemas/*.gschema.xml "${pkgdir}/usr/share/glib-2.0/schemas/"
fi
}
|
