blob: 319196d3dfa9dca60c84ccb9eb1947121fab3212 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Contributor (Arch): Kevin MacMartin <prurigro@gmail.com>
# Contributor (Arch): openfbt
# Contributor (Arch): Werecat
# Contributor (Arch): Xyne
# Maintainer : Omar Vega Ramos <ovruni@gnu.org.pe>
_pkgname=cjdns
pkgname=$_pkgname-git
pkgver=0.3.3328
pkgrel=1
pkgdesc='A routing engine designed for security, scalability, speed and ease of use'
url='https://github.com/cjdelisle/cjdns'
license=('GPL3')
arch=('i686' 'x86_64')
options=('!distcc' '!strip' '!buildflags')
depends=('glibc')
makedepends=('git' 'nodejs' 'python2')
optdepends=(
'cjdnsify: allows you to run some programs bound to your cjdns address'
'libnacl: speed up the build process by skipping the need to compile cnacl'
'cjdns-git-sysvinit: support for sysvinit (rc.d)'
)
source=("git+$url#branch=crashey")
sha512sums=('SKIP')
pkgver() {
cd $_pkgname
git describe --always | sed 's|-|.|g;s|[^\.]*\.||;s|\.[^\.]*$||'
}
build() {
cd $_pkgname
bash 'do'
}
package() {
cd $_pkgname
install -Dm755 'cjdroute' "$pkgdir/usr/bin/cjdroute"
install -Dm755 'contrib/sh/run-cjdroute.sh' "$pkgdir/usr/bin/run-cjdroute"
install -Dm644 "contrib/systemd/$_pkgname.service" "$pkgdir/usr/lib/systemd/system/$_pkgname.service"
install -Dm644 'doc/man/cjdroute.conf.5' "$pkgdir/usr/share/man/man5/cjdroute.conf.5"
}
|
