blob: 48071b970e2a0898aba6f4229cb7aa5bbe8143cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 239800 2015-05-26 17:10:07Z bpiotrowski $
# Contributor (Arch): FUBAR <mrfubar@gmail.com>
# Contributor (Arch): simo <simo@archlinux.org>
# Contributor (Arch): Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor (Arch): Gaetan Bisson <bisson@archlinux.org>
# Maintainer (Arch): Dave Reisner <dreisner@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=bitlbee-libpurple
_pkgname=bitlbee
pkgver=3.4
pkgrel=1.parabola1
pkgdesc='Brings instant messaging (XMPP, MSN, Yahoo!, AIM, ICQ, Twitter) to IRC, without nonfree Skype support'
url='http://www.bitlbee.org/'
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('gnutls' 'glib2' 'libpurple-minimal')
makedepends=('asciidoc' 'libotr')
optdepends=('libotr: for OTR encryption support')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
source=("http://get.bitlbee.org/src/$_pkgname-$pkgver.tar.gz"
'bitlbee.tmpfiles')
sha1sums=('3b22d9da741903a293fe3c25511448276c75b58a'
'3695ed2fe22436c4d0fc3ead829f7d1f89bc491c')
backup=('etc/bitlbee/bitlbee.conf'
'etc/bitlbee/motd.txt')
install=bitlbee.install
build() {
cd "$_pkgname-$pkgver"
./configure \
--prefix=/usr \
--etcdir=/etc/bitlbee \
--sbindir=/usr/bin \
--pidfile=/run/bitlbee/bitlbee.pid \
--ipcsocket=/run/bitlbee/bitlbee.sock \
--systemdsystemunitdir=/usr/lib/systemd/system \
--ssl=gnutls \
--strip=0 \
--otr=plugin \
--skype=0 \
--purple=1
make
}
package() {
make -C "$_pkgname-$pkgver" DESTDIR="$pkgdir" install{,-etc,-dev,-systemd}
install -o65 -g65 -dm770 "$pkgdir/var/lib/bitlbee"
install -Dm644 "$srcdir/bitlbee.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/bitlbee.conf"
}
|
