blob: 2e3e7cf91f059e4f6785bc00413b04ab681b6fb8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer (Manjaro): artoo <artoo@manjaro.org>
# Contributor (Manjaro): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Manjaro): Ionut Biru <ibiru@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_pkgname=accountsservice
_commit=dac425433270c6dc38feba4d2513e4da7bd265fd # tags/0.6.43^0
pkgname=accountsservice-elogind
pkgver=0.6.42+12+gdac4254
pkgrel=2
pkgdesc="D-Bus interface for user account query and manipulation"
url="https://www.freedesktop.org/software/accountsservice/"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL3')
provides=('accountsservice')
conflicts=('accountsservice')
depends=('glib2' 'elogind' 'polkit-elogind')
makedepends=('intltool' 'gtk-doc' 'gobject-introspection' 'git')
source=("git://anongit.freedesktop.org/accountsservice#commit=$_commit"
'accountsservice-enable-elogind.patch')
sha256sums=('SKIP'
'dc233c540cf3e129479aa0c5e408a706a8c8cd52fdb94ad50aba32f8e9f765e1')
pkgver() {
cd $_pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $_pkgname
patch -Np 1 -i ${srcdir}/accountsservice-enable-elogind.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $_pkgname
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/$_pkgname \
--disable-static \
--enable-elogind \
--enable-admin-group="wheel" \
--disable-systemd \
--enable-gtk-doc
make
}
package() {
cd $_pkgname
make DESTDIR="$pkgdir" install
}
|
