blob: 058b160a73b6b851bf6fe35d346faf15a0d56139 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: David P. <megver83@parabola.nu>
# Contributor: Alexey D. <lq07829icatm@rambler.ru>
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgname=udisks2-elogind
pkgver=2.6.4
pkgrel=1
pkgdesc="Disk Management Service, version 2"
arch=('armv7h' 'i686' 'x86_64')
url="http://www.freedesktop.org/wiki/Software/udisks"
license=('GPL2')
depends=('glib2' 'polkit-elogind' 'libatasmart' 'libgudev' 'acl' 'eudev-systemd')
makedepends=('intltool' 'docbook-xsl' 'gobject-introspection' 'python2' 'gnome-common')
optdepends=('parted: partition management'
'gptfdisk: GUID partition table support'
'ntfs-3g: NTFS filesystem management support'
'dosfstools: VFAT filesystem management support')
provides=("udisks2=${pkgver}")
conflicts=('udisks2')
options=(libtool strip)
source=(https://github.com/storaged-project/udisks/releases/download/udisks-${pkgver}/udisks-${pkgver}.tar.bz2
'udisks-enable-elogind.patch')
sha256sums=('d65389a861a9a475d3c8e0ad2b8603d9961977f1a00024093b5bacd711e774f2'
'7d47a00ce6d484140a09939e08678b72d9a0212490d70a1d150b06b21b413ba9')
prepare(){
cd "udisks-$pkgver"
patch -Np 1 -i ${srcdir}/udisks-enable-elogind.patch
autoreconf -vfi
}
build() {
cd "udisks-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--disable-static \
--sbindir=/usr/bin \
--libexecdir=/usr/lib
make
# fix mdadm location
sed -i -e 's#/sbin/mdadm#/usr/bin/mdadm#g' \
"${srcdir}/udisks-${pkgver}"/data/80-udisks2.rules
}
package() {
cd "udisks-$pkgver"
make DESTDIR="$pkgdir" install \
bash_completiondir=/usr/share/bash-completion/completions
}
|
