blob: a5ac313d1018f036b6827b92e4ee94d3fb354020 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Maintainer: André Silva <emulatorman@parabola.nu>
# Maintainer: Márcio Silva <coadde@parabola.nu>
# Based on pcsx2 (parabola) package
_pkgname=pcsx2
pkgname=pcsx2-git
pkgver=r8317.247d33a
pkgrel=1.parabola1
pkgdesc='A Sony PlayStation 2 emulator, without nonfree nvidia-cg-toolkit support'
arch=('i686' 'x86_64')
url='http://www.pcsx2.net'
license=('GPL2' 'GPL3' 'LGPL2.1' 'LGPL3')
depends_i686=('glew' 'libaio' 'libcanberra' 'libjpeg-turbo'
'portaudio' 'sdl2' 'soundtouch' 'wxgtk')
depends_x86_64=('lib32-glew' 'lib32-libaio' 'lib32-libcanberra'
'lib32-libjpeg-turbo'
'lib32-portaudio' 'lib32-sdl2' 'lib32-soundtouch' 'lib32-wxgtk')
makedepends=('cmake' 'git')
makedepends_x86_64=('gcc-multilib')
optdepends_x86_64=('lib32-gtk-engines: GTK2 engines support'
'lib32-gtk-engine-murrine: Murrine GTK3 engine support'
'lib32-gtk-engine-unico: Unico GTK2 engine support')
provides=("${_pkgname}")
conflicts=("${_pkgname}" "${_pkgname}-libre")
replaces=("${_pkgname}-libre")
options=('!emptydirs')
source=(${pkgname}-${pkgver}::git+https://github.com/PCSX2/pcsx2.git)
sha256sums=('SKIP')
pkgver() {
cd ${pkgname}-${pkgver}
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ${pkgname}-${pkgver}
# remove zzogl and zerogs plugins (depends nonfree nvidia-cg-toolkit)
rm -vr plugins/{zerogs,zzogl-pg}
sed -i '\|# ZZOGL|,+6 d' linux_various/glsl2h.pl
}
build() {
cd ${pkgname}-${pkgver}
if [[ -d build ]]; then
rm -rf build
fi
mkdir build && cd build
if [[ $CARCH == i686 ]]; then
cmake .. \
-DCMAKE_BUILD_TYPE='Release' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DCMAKE_LIBRARY_PATH='/usr/lib' \
-DPLUGIN_DIR='/usr/lib/pcsx2' \
-DGAMEINDEX_DIR='/usr/share/pcsx2' \
-DDISABLE_ADVANCE_SIMD='TRUE' \
-DEXTRA_PLUGINS='TRUE' \
-DREBUILD_SHADER='TRUE' \
-DGLSL_API='TRUE' \
-DPACKAGE_MODE='TRUE' \
-DXDG_STD='TRUE'
elif [[ $CARCH == x86_64 ]]; then
cmake .. \
-DCMAKE_BUILD_TYPE='Release' \
-DCMAKE_TOOLCHAIN_FILE='cmake/linux-compiler-i386-multilib.cmake' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DCMAKE_LIBRARY_PATH='/usr/lib32' \
-DPLUGIN_DIR='/usr/lib32/pcsx2' \
-DGAMEINDEX_DIR='/usr/share/pcsx2' \
-DDISABLE_ADVANCE_SIMD='TRUE' \
-DEXTRA_PLUGINS='TRUE' \
-DREBUILD_SHADER='TRUE' \
-DGLSL_API='TRUE' \
-DPACKAGE_MODE='TRUE' \
-DXDG_STD='TRUE'
fi
make
}
package() {
cd ${pkgname}-${pkgver}/build
make DESTDIR="${pkgdir}" install
# create pcsx2 binary link and copy PCSX2.1 to pcsx2.1 man page
ln -vs PCSX2 ${pkgdir}/usr/bin/pcsx2
cp -va ${pkgdir}/usr/share/man/man1/{PCSX,pcsx}2.1
}
# vim: ts=2 sw=2 et:
|
