nonsystemd/your-initfreedom/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-initfreedom
pkgdesc="This package conflicts with every package known to work only for/with systemd."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20210628
_gitver=50cf92a24fa5e2a6e4d70b90fbabd161dc2554e3
pkgrel=1

arch=('any')
install=${pkgname}.install

makedepends=(librelib)
source=(blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/${pkgname}-blacklist.txt?id=${_gitver})
sha512sums=('b0a421a21eedde392d77d1b2264e7d71f4725e89481bca7a01afb25e95a51edeb10a4e7f5fadd31bd243cfdfcdb40d32215f497c994d938c5907223ef8ce9e28')

package() {
	cd "$srcdir"

	conflicts=($( \
		< blacklist-${_gitver}.txt \
		libreblacklist normalize | \
		cut -d: -f1,2 | \
		sed -n 's/:$//p' | \
		sort -u \
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}