blob: 30a75bfcd51cc46b00dadb4f44bd56a319be9ee4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
pkgbase=pipewire
pkgname=(pipewire alsa-card-profiles pipewire-docs pipewire-media-session
pipewire-alsa pipewire-jack pipewire-pulse gst-plugin-pipewire)
pkgver=0.3.25
pkgrel=1
pkgrel+=.nonsystemd1
epoch=1
pkgdesc="Low-latency audio/video router and processor"
url="https://pipewire.org"
license=(LGPL)
arch=(x86_64)
arch+=(i686 armv7h)
makedepends=(git meson doxygen graphviz xmltoman valgrind libpulse alsa-lib
gst-plugins-base rtkit dbus sdl2 ncurses libsndfile bluez-libs sbc
libldac libopenaptx libfdk-aac vulkan-headers vulkan-icd-loader)
checkdepends=(desktop-file-utils)
_commit=c324107211718043553337cb10d022fe9d2d12d8 # tags/0.3.25
source=("git+https://gitlab.freedesktop.org/pipewire/pipewire.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgbase
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgbase
}
build() {
arch-meson $pkgbase build \
-D docs=enabled \
-D systemd=disabled \
-D jack=disabled \
-D libcamera=disabled \
-D udevrulesdir=/usr/lib/udev/rules.d
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
_ver=${pkgver:0:3}
package_pipewire() {
depends=(rtkit alsa-card-profiles libdbus-1.so libncursesw.so libsndfile.so
libudev.so libasound.so libbluetooth.so libsbc.so
libldacBT_enc.so libopenaptx.so libfdk-aac.so libvulkan.so)
optdepends=('pipewire-docs: Documentation'
'pipewire-media-session: Default session manager'
'pipewire-alsa: ALSA configuration'
'pipewire-jack: JACK support'
'pipewire-pulse: PulseAudio replacement'
'gst-plugin-pipewire: GStreamer support')
provides=(libpipewire-$_ver.so)
backup=(etc/pipewire/{pipewire{,-pulse},client{,-rt}}.conf)
DESTDIR="$pkgdir" meson install -C build
cd "$pkgdir"
_pick acp usr/lib/udev
_pick acp usr/share/alsa-card-profile
_pick docs usr/share/doc
_pick pms etc/pipewire/media-session.d/*.conf
_pick pms usr/bin/pipewire-media-session
_pick jack etc/pipewire/{jack.conf,media-session.d/with-jack}
_pick jack usr/bin/pw-jack usr/lib/pipewire-$_ver/jack
_pick jack usr/share/man/man1/pw-jack.1
_pick pulse etc/pipewire/media-session.d/with-pulseaudio
_pick gst usr/lib/gstreamer-1.0
}
package_alsa-card-profiles() {
pkgdesc+=" - ALSA card profiles"
mv acp/* "$pkgdir"
}
package_pipewire-docs() {
pkgdesc+=" - documentation"
mv docs/* "$pkgdir"
}
package_pipewire-media-session() {
pkgdesc+=" - Session manager"
depends=(pipewire libpipewire-$_ver.so)
backup=(etc/pipewire/media-session.d/media-session.conf
etc/pipewire/media-session.d/{alsa,bluez,v4l2}-monitor.conf)
mv pms/* "$pkgdir"
}
package_pipewire-alsa() {
pkgdesc+=" - ALSA configuration"
depends=(pipewire-media-session)
provides=(pulseaudio-alsa)
mkdir -p "$pkgdir/etc/alsa/conf.d"
ln -st "$pkgdir/etc/alsa/conf.d" \
/usr/share/alsa/alsa.conf.d/{50-pipewire,99-pipewire-default}.conf
install -Dm644 /dev/null "$pkgdir/etc/pipewire/media-session.d/with-alsa"
}
package_pipewire-jack() {
pkgdesc+=" - JACK support"
depends=(pipewire-media-session libpipewire-$_ver.so)
backup=(etc/pipewire/jack.conf)
mv jack/* "$pkgdir"
}
package_pipewire-pulse() {
pkgdesc+=" - PulseAudio replacement"
depends=(pipewire-media-session libpulse)
provides=(pulseaudio pulseaudio-bluetooth)
conflicts=(pulseaudio pulseaudio-bluetooth)
mv pulse/* "$pkgdir"
}
package_gst-plugin-pipewire() {
pkgdesc="Multimedia graph framework - pipewire plugin"
depends=(pipewire-media-session libpipewire-$_ver.so gst-plugins-base-libs)
mv gst/* "$pkgdir"
}
# vim:set sw=2 et:
|
