blob: f87167be69d6aeea17899db9131f5d262c771ba9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Maintainer: David P. <megver83@parabola.nu>
pkgbase=p11-kit
pkgname=(p11-kit libp11-kit)
pkgver=0.23.20
pkgrel=3
pkgrel+=.nonsystemd1
pkgdesc="Loads and enumerates PKCS#11 modules"
url="https://p11-glue.freedesktop.org"
arch=(x86_64)
arch+=(i686 armv7h)
license=(BSD)
makedepends=(gtk-doc git meson libtasn1 libffi)
source=("git+https://github.com/p11-glue/p11-kit?signed#tag=$pkgver")
sha256sums=('SKIP')
validpgpkeys=('C0F67099B808FB063E2C81117BFB1108D92765AF' # Stef Walter
'462225C3B46F34879FC8496CD605848ED7E69871') # Daiki Ueno
prepare() {
cd p11-kit
}
build() {
arch-meson p11-kit build \
--buildtype debugoptimized \
-D gtk_doc=true \
-D man=true \
-D trust_paths=/etc/ca-certificates/trust-source:/usr/share/ca-certificates/trust-source \
-D systemd=disabled
ninja -C build
}
check() {
meson test -C build --print-errorlogs
}
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
package_p11-kit() {
depends=("libp11-kit=$pkgver-$pkgrel" libp11-kit.so)
DESTDIR="$pkgdir" meson install -C build
ln -sr "$pkgdir/usr/bin/update-ca-trust" "$pkgdir/usr/lib/p11-kit/trust-extract-compat"
# Split libp11-kit
_pick lib "$pkgdir"/usr/include
_pick lib "$pkgdir"/usr/lib/{p11-kit-proxy.so,libp11-kit.*}
_pick lib "$pkgdir"/usr/lib/{pkcs11,pkgconfig}
_pick lib "$pkgdir"/usr/share/{locale,p11-kit}
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 p11-kit/COPYING
}
package_libp11-kit() {
pkgdesc+=" (library)"
depends=(glibc libtasn1 libffi)
provides=(libp11-kit.so)
mv lib/* "$pkgdir"
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 p11-kit/COPYING
}
# vim:set ts=2 sw=2 et:
|
