blob: cd96351ebc961a9169d24088c6a8a2c43cb74b92 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Tom Gundersen <teg@jklm.no>
# Contributor (Arch): Link Dupont <link@subpop.net>
pkgname=dbus
pkgver=1.12.16
pkgrel=2
pkgrel+=.nonsystemd2
pkgdesc="Freedesktop.org message bus system"
url="https://wiki.freedesktop.org/www/Software/dbus/"
arch=(x86_64 i686 armv7h)
license=(GPL custom)
depends=(libx11 libelogind expat audit)
makedepends=(elogind xmlto docbook-xsl python yelp-tools doxygen git autoconf-archive graphviz)
provides=(libdbus dbus-openrc dbus-elogind)
conflicts=(${provides[@]})
replaces=(${provides[@]})
_commit=23cc709db8fab94f11fa48772bff396b20aea8b0 # tags/dbus-1.12.16^0
source=("git+https://gitlab.freedesktop.org/dbus/dbus.git#commit=$_commit"
'dbus-enable-elogind.patch'
'dbus.initd')
sha256sums=('SKIP'
'faffcaa5b295f49fcedeed2c9ece5298949096be3062fd99a4bf1a6ac3ad1ea0'
'00a1a8f254d4f40b6f98a2777809b9c45ad81c4aeb4c0592793dd839777990bd')
validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90' # Simon McVittie <simon.mcvittie@collabora.co.uk>
'3C8672A0F49637FE064AC30F52A43A1E4B77B059') # Simon McVittie <simon.mcvittie@collabora.co.uk>
pkgver() {
cd dbus
git describe --tags | sed 's/^dbus-//;s/-/+/g'
}
prepare() {
cd dbus
# Reduce docs size
printf '%s\n' >>Doxyfile.in \
HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
patch -Np 1 -i ${srcdir}/dbus-enable-elogind.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd dbus
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/dbus-1.0 \
--with-console-auth-dir=/run/console/ \
--with-dbus-user=dbus \
--with-system-pid-file=/run/dbus/pid \
--with-system-socket=/run/dbus/system_bus_socket \
--without-systemdsystemunitdir \
--enable-inotify \
--disable-systemd \
--disable-user-session \
--disable-static \
--disable-verbose-mode \
--disable-asserts \
--disable-checks \
--enable-elogind \
--enable-x11-autolaunch
make
}
check() {
make -C dbus check
}
package() {
DESTDIR="$pkgdir" make -C dbus install
rm -r "$pkgdir/var/run"
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 dbus/COPYING
# We have a pre-assigned uid (81)
echo 'u dbus 81 "System Message Bus"' |
install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/dbus.conf"
# Split docs
mv "$pkgdir/usr/share/doc" "$srcdir"
# Init script
install -Dm755 "$srcdir/dbus.initd" "$pkgdir/etc/init.d/dbus"
sed -i 's|dbus.pid|dbus/pid|g' "$pkgdir/etc/init.d/dbus"
}
# vim:set sw=2 et:
|
