blob: e0478646ed47de91703a6df983e1b38b2f59e4c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
pkgname=lib32-dbus
pkgver=1.12.20
pkgrel=1.1
pkgrel+=.nonsystemd1
pkgdesc="Freedesktop.org message bus system (32-bit)"
url="https://wiki.freedesktop.org/www/Software/dbus/"
arch=(x86_64)
license=(GPL custom)
depends=(lib32-elogind dbus)
makedepends=(lib32-glib2 lib32-expat git autoconf-archive)
source=("git+https://gitlab.freedesktop.org/dbus/dbus.git?signed#tag=dbus-$pkgver"
no-fatal-warnings.diff)
sha256sums=('SKIP'
'6958eeec07557b92a28419eb1702331ee2f0a6fd17285e37dfb6130b9fa4cf6e')
validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90') # Simon McVittie <simon.mcvittie@collabora.co.uk>
prepare() {
cd dbus
# Allow us to enable checks without them being fatal
patch -Np1 -i ../no-fatal-warnings.diff
NOCONFIGURE=1 ./autogen.sh
}
build() {
export CC="gcc -m32 -mstackrealign"
export CXX="g++ -m32 -mstackrealign"
export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
cd dbus
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libdir=/usr/lib32 \
--libexecdir=/usr/lib/dbus-1.0 \
runstatedir=/run \
--with-console-auth-dir=/run/console/ \
--with-dbus-user=dbus \
--with-system-pid-file=/run/dbus/pid \
--with-system-socket=/run/dbus/system_bus_socket \
--disable-systemd \
--without-systemdsystemunitdir \
--enable-inotify \
--disable-libaudit \
--enable-user-session \
--disable-xml-docs \
--disable-doxygen-docs \
--disable-ducktype-docs \
--disable-static \
--without-x
make
}
check() {
make -C dbus check
}
package() {
provides=(lib32-libdbus libdbus-1.so)
conflicts=(lib32-libdbus)
replaces=(lib32-libdbus)
DESTDIR="$pkgdir" make -C dbus install
rm -r "$pkgdir"/{etc,var}
rm -r "$pkgdir"/usr/{bin,include,lib,share}
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 dbus/COPYING
}
# vim:set sw=2 et:
|
