blob: fb4dcb993218d897a9620bc05210615bd950b740 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# $Id: PKGBUILD 285668 2017-01-11 13:15:17Z arojas $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Contributor (Arch): Tobias Kieslich <tobias@justdreams.de>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
pkgname=gthumb
pkgver=3.4.4.1
pkgrel=2.nonprism1
pkgdesc="Image browser and viewer for the GNOME Desktop, without support for unsafe and dangerous for privacy protocols"
url="https://wiki.gnome.org/Apps/gthumb"
arch=(i686 x86_64)
license=(GPL)
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=(dconf librsvg clutter-gtk gst-plugins-base-libs gsettings-desktop-schemas libwebp
libsecret libsoup webkit2gtk json-glib)
makedepends=(intltool libchamplain exiv2 itstool brasero libraw liboauth docbook-xsl
yelp-tools flex gnome-common git)
optdepends=('libraw: read RAW files'
'exiv2: metadata support'
'libchamplain: map viewer'
'brasero: burn discs'
'liboauth: web albums')
_commit=849e68f5ba606c25988a1e9e6669519734a7449a # gthumb-3-4
source=("git://git.gnome.org/gthumb#commit=$_commit"
nonprism.patch)
sha256sums=('SKIP'
'b1cd2463ab6475ce91a2b2e83dfcb1835ffaa9640c59d7bcfbe611163327fa45')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
# Fixup tags for pkgver()
git tag -f 3.4.4.1 849e68f5ba606c25988a1e9e6669519734a7449a
NOCONFIGURE=1 ./autogen.sh
patch -Np1 -i ../nonprism.patch
}
build() {
cd $pkgname
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--enable-libchamplain
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $pkgname
make check
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
