blob: cc1e2ee1266ee387c53d6611c552793e99a59b78 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
pkgname=gnome-online-accounts
pkgver=3.26.1
pkgrel=1.nonprism1
arch=(i686 x86_64 armv7h)
pkgdesc="Single sign-on framework for GNOME, without support for unsafe and dangerous for privacy protocols"
url="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
license=(LGPL)
depends=(webkit2gtk json-glib libnotify rest libsecret telepathy-glib krb5 gcr)
makedepends=(intltool gobject-introspection gtk-doc vala git gnome-common)
optdepends=('gvfs-goa: Virtual file systems (e.g. OwnCloud)')
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism" )
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
_commit=b36db9948f24637c37c6485a129757498454c5ea # tags/3.26.1^0
source=("git+https://git.gnome.org/browse/gnome-online-accounts#commit=$_commit"
"git+https://git.gnome.org/browse/telepathy-account-widgets")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
git submodule init
git config --local submodule.telepathy-account-widgets.url "$srcdir/telepathy-account-widgets"
git submodule update
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure \
--prefix=/usr \
--libexecdir=/usr/lib/$pkgname \
--disable-static \
--enable-gtk-doc \
--enable-media-server \
--enable-kerberos \
--enable-telepathy \
--enable-owncloud \
--enable-imap-smtp \
--disable-lastfm \
--disable-exchange \
--disable-facebook \
--disable-flickr \
--disable-google \
--disable-pocket \
--disable-windows-live \
--disable-twitter \
--disable-yahoo \
--disable-foursquare
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
