blob: 2ea4c56507888a50df10de7fcb79fc53df5a9ddd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# $Id: PKGBUILD 285635 2017-01-10 19:04:29Z heftig $
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=gnome-online-accounts
pkgver=3.22.4
pkgrel=1.nonprism1
pkgdesc="Single sign-on framework for GNOME, without support for unsafe and dangerous for privacy protocols"
url="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
arch=(i686 x86_64)
license=(LGPL)
depends=(webkit2gtk json-glib libnotify rest libsecret telepathy-glib krb5 gcr)
makedepends=(intltool gobject-introspection gtk-doc vala git gnome-common)
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism" )
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
optdepends=('gvfs-goa: Virtual file systems (e.g. OwnCloud)')
_commit=9b02ee9436072d46eb54cd309ab1ff1b7c0dbcb6 # tags/3.22.4^0
source=("git+https://git.gnome.org/browse/gnome-online-accounts#commit=$_commit"
"git+https://git.gnome.org/browse/telepathy-account-widgets")
sha256sums=('SKIP'
'SKIP')
prepare() {
cd $pkgname
git submodule init
git config --local submodule.telepathy-account-widgets.url "$srcdir/telepathy-account-widgets"
git submodule update
NOCONFIGURE=1 ./autogen.sh
}
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
build() {
cd $pkgname
./configure \
--prefix=/usr \
--libexecdir=/usr/lib/$pkgname \
--disable-static \
--enable-media-server \
--disable-kerberos \
--enable-lastfm \
--enable-gtk-doc \
--disable-exchange \
--disable-facebook \
--disable-flickr \
--disable-google \
--enable-imap-smtp \
--enable-owncloud \
--disable-pocket \
--enable-telepathy \
--disable-windows-live \
--disable-twitter \
--disable-yahoo \
--disable-foursquare
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
